Index of Functions: A  B  C  D  E  F  G  H  I  J  K  L  M  N  O  P  Q  R  S  T  U  V  W  X 
Index Page
cspice_cylsph

Table of contents
Abstract
I/O
Parameters
Examples
Particulars
Exceptions
Files
Restrictions
Required_Reading
Literature_References
Author_and_Institution
Version
Index_Entries


Abstract


   CSPICE_CYLSPH converts cylindrical coordinates to spherical
   coordinates.

I/O


   Given:

      r        the scalar double precision value for distance of the point from
               Z-axis.

               help, r
                  DOUBLE = Scalar

      clon     the scalar double precision value for the cylindrical angle of
               the point from XZ plane as measured in radians.

               help, clon
                  DOUBLE = Scalar

      z        the scalar double precision value for the height of the point
               above XY plane.

               help, z
                  DOUBLE = Scalar

   the call:

      cspice_cylsph, r, clon, z, radius, colat, slon

   returns:

      radius   the scalar double precision distance of the point from origin.

               help, radius
                  DOUBLE = Scalar

      colat    the scalar double precision polar angle (co-latitude) of the
               point measured in radians.

               help, colat
                  DOUBLE = Scalar

      slon     the scalar double precision azimuthal angle (longitude) of the
               point measured in radians.

               help, slon
                  DOUBLE = Scalar

Parameters


   None.

Examples


   Any numerical results shown for these examples may differ between
   platforms as the results depend on the SPICE kernels used as input
   and the machine specific arithmetic implementation.

   1) Compute the cylindrical coordinates of the position of the
      Moon as seen from the Earth, and convert them to spherical
      and rectangular coordinates.

      Use the meta-kernel shown below to load the required SPICE
      kernels.


         KPL/MK

         File name: cylsph_ex1.tm

         This meta-kernel is intended to support operation of SPICE
         example programs. The kernels shown here should not be
         assumed to contain adequate or correct versions of data
         required by SPICE-based user applications.

         In order for an application to use this meta-kernel, the
         kernels referenced here must be present in the user's
         current working directory.

         The names and contents of the kernels referenced
         by this meta-kernel are as follows:

            File name                     Contents
            ---------                     --------
            de421.bsp                     Planetary ephemeris
            naif0012.tls                  Leapseconds


         \begindata

            KERNELS_TO_LOAD = ( 'de421.bsp',
                                'naif0012.tls'  )

         \begintext

         End of meta-kernel


      Example code begins here.


      PRO cylsph_ex1

         ;;
         ;; Load SPK and LSK kernels, use a meta kernel for
         ;; convenience.
         ;;
         cspice_furnsh, 'cylsph_ex1.tm'

         ;;
         ;; Look up the geometric state of the Moon as seen from
         ;; the Earth at 2017 Mar 20, relative to the J2000
         ;; reference frame.
         ;;
         cspice_str2et, '2017 Mar 20', et

         cspice_spkpos, 'Moon', et, 'J2000', 'NONE', 'Earth', pos, ltime

         ;;
         ;; Convert the position vector `pos' to cylindrical
         ;; coordinates.
         ;;
         cspice_reccyl, pos, r, clon, z

         ;;
         ;; Convert the cylindrical coordinates to spherical.
         ;;
         cspice_cylsph, r, clon, z, radius, colat, slon

         ;;
         ;; Convert the spherical coordinates to rectangular.
         ;;
         cspice_sphrec, radius, colat, slon, rectan

         print, ' '
         print, 'Original rectangular coordinates:'
         print, ' '
         print, format='(A,F20.8)', ' X           (km): ', pos[0]
         print, format='(A,F20.8)', ' Y           (km): ', pos[1]
         print, format='(A,F20.8)', ' Z           (km): ', pos[2]
         print, ' '
         print, 'Cylindrical coordinates:'
         print, ' '
         print, format='(A,F20.8)', ' Radius      (km): ', r
         print, format='(A,F20.8)', ' Longitude  (deg): ',                   $
                                    clon*cspice_dpr( )
         print, format='(A,F20.8)', ' Z           (km): ', z
         print, ' '
         print, 'Spherical coordinates:'
         print, ' '
         print, format='(A,F20.8)', ' Radius      (km): ', radius
         print, format='(A,F20.8)', ' Colatitude (deg): ',                   $
                                    colat*cspice_dpr( )
         print, format='(A,F20.8)', ' Longitude  (deg): ',                   $
                                    slon*cspice_dpr( )
         print, ' '
         print, 'Rectangular coordinates from cspice_sphrec:'
         print, ' '
         print, format='(A,F20.8)', ' X           (km): ', rectan[0]
         print, format='(A,F20.8)', ' Y           (km): ', rectan[1]
         print, format='(A,F20.8)', ' Z           (km): ', rectan[2]
         print, ' '

         ;;
         ;; It's always good form to unload kernels after use,
         ;; particularly in IDL due to data persistence.
         ;;
         cspice_kclear

      END


      When this program was executed on a Mac/Intel/IDL8.x/64-bit
      platform, the output was:


      Original rectangular coordinates:

       X           (km):      -55658.44323296
       Y           (km):     -379226.32931475
       Z           (km):     -126505.93063865

      Cylindrical coordinates:

       Radius      (km):      383289.01777726
       Longitude  (deg):         261.65040211
       Z           (km):     -126505.93063865

      Spherical coordinates:

       Radius      (km):      403626.33912495
       Colatitude (deg):         108.26566077
       Longitude  (deg):         261.65040211

      Rectangular coordinates from cspice_sphrec:

       X           (km):      -55658.44323296
       Y           (km):     -379226.32931475
       Z           (km):     -126505.93063865


   2) Create a table showing a variety of cylindrical coordinates
      and the corresponding spherical coordinates.

      Corresponding spherical and cylindrical coordinates are
      listed to three decimal places. All input and output angles
      are in degrees.


      Example code begins here.


      PRO cylsph_ex2

         ;;
         ;; Define six sets of cylindrical coordinates, `clon'
         ;; expressed in degrees.
         ;;
         r     = [ 1.d,  1.d,   1.d,   1.d,   0.d,  0.d ]
         clon  = [ 0.d, 90.d, 180.d, 180.d, 180.d, 33.d ]
         z     = [ 0.d,  0.d,   1.d,  -1.d,   1.d,  0.d ]

         ;;
         ;; Print a header for the data output.
         ;;
         print, '     r       clon      z   ', $
                '   radius    slon    colat '
         print, '  -------  -------  -------', $
                '  -------  -------  -------'

         ;;
         ;; Loop over each set of coordinates...
         ;;
         for i=0, 5 do begin

            ;;
            ;; ...convert the `clon' values from degrees to radians
            ;;
            cspice_convrt, clon[i], 'DEGREES', 'RADIANS', lonc_rads

            ;;
            ;; ..convert the cylindrical coordinates to spherical
            ;; coordinates
            ;;
            cspice_cylsph, r[i], lonc_rads, z[i], radius, colat, slon

            ;;
            ;; ...convert the `slon' and `colat' values from radians
            ;; to degrees
            ;;
            cspice_convrt, slon,  'RADIANS', 'DEGREES', slon_degs
            cspice_convrt, colat, 'RADIANS', 'DEGREES', colat_degs

            ;;
            ;; Print the input and corresponding output.
            ;;
            print, FORMAT='(6D9.3)', r[i], clon[i], z[i], $
                                     radius, slon_degs, colat_degs

         endfor

      END


      When this program was executed on a Mac/Intel/IDL8.x/64-bit
      platform, the output was:


           r       clon      z      radius    slon    colat
        -------  -------  -------  -------  -------  -------
          1.000    0.000    0.000    1.000    0.000   90.000
          1.000   90.000    0.000    1.000   90.000   90.000
          1.000  180.000    1.000    1.414  180.000   45.000
          1.000  180.000   -1.000    1.414  180.000  135.000
          0.000  180.000    1.000    1.000  180.000    0.000
          0.000   33.000    0.000    0.000   33.000    0.000


Particulars


   This returns the spherical coordinates of a point whose position
   is input through cylindrical coordinates.

Exceptions


   1)  If any of the input arguments, `r', `clon' or `z', is
       undefined, an error is signaled by the IDL error handling
       system.

   2)  If any of the input arguments, `r', `clon' or `z', is not of
       the expected type, or it does not have the expected dimensions
       and size, an error is signaled by the Icy interface.

   3)  If any of the output arguments, `radius', `colat' or `slon',
       is not a named variable, an error is signaled by the Icy
       interface.

Files


   None.

Restrictions


   None.

Required_Reading


   ICY.REQ

Literature_References


   None.

Author_and_Institution


   J. Diaz del Rio     (ODC Space)
   E.D. Wright         (JPL)

Version


   -Icy Version 1.0.1, 10-AUG-2021 (JDR)

       Edited the -Examples section to comply with NAIF standard.
       Added complete code examples.

       Changed the argument names "lonc" and "lon" to "clon" and "slon"
       for consistency with other routines.

       Added -Parameters, -Exceptions, -Files, -Restrictions,
       -Literature_References and -Author_and_Institution sections, and
       completed -Particulars section.

       Removed reference to the routine's corresponding CSPICE header from
       -Abstract section.

       Added arguments' type and size information in the -I/O section.

   -Icy Version 1.0.0, 16-JUN-2003 (EDW)

Index_Entries


   cylindrical to spherical



Fri Dec 31 18:43:02 2021