Table of contents
CSPICE_RECCYL converts rectangular (Cartesian) coordinates to
cylindrical coordinates.
Given:
rectan a double precision 3-vector or 3xN array
containing the rectangular coordinates of a
position or set of positions.
help, rectan
DOUBLE = Array[3] or DOUBLE = Array[3,N]
the call:
cspice_reccyl, rectan, r, clon, z
returns:
r a double precision scalar or N-vector describing the distance of
the point from Z-axis.
help, r
DOUBLE = Scalar or DOUBLE = Array[N]
clon a double precision scalar or N-vector describing the cylindrical
angle of the point from XZ plane as measured in radians.
help, clon
DOUBLE = Scalar or DOUBLE = Array[N]
z a double precision scalar or N-vector describing the height of
the point above XY plane.
help, z
DOUBLE = Scalar or DOUBLE = Array[N]
`r', `clon', and `z' return with the same measure of
vectorization (N) as `rectan'.
None.
Any numerical results shown for these examples may differ between
platforms as the results depend on the SPICE kernels used as input
and the machine specific arithmetic implementation.
1) Compute the cylindrical coordinates of the position of the Moon
as seen from the Earth, and convert them to rectangular
coordinates.
Use the meta-kernel shown below to load the required SPICE
kernels.
KPL/MK
File name: reccyl_ex1.tm
This meta-kernel is intended to support operation of SPICE
example programs. The kernels shown here should not be
assumed to contain adequate or correct versions of data
required by SPICE-based user applications.
In order for an application to use this meta-kernel, the
kernels referenced here must be present in the user's
current working directory.
The names and contents of the kernels referenced
by this meta-kernel are as follows:
File name Contents
--------- --------
de421.bsp Planetary ephemeris
naif0012.tls Leapseconds
\begindata
KERNELS_TO_LOAD = ( 'de421.bsp',
'naif0012.tls' )
\begintext
End of meta-kernel
Example code begins here.
PRO reccyl_ex1
;;
;; Load SPK and LSK kernels, use a meta kernel for
;; convenience.
;;
cspice_furnsh, 'reccyl_ex1.tm'
;;
;; Look up the geometric state of the Moon as seen from
;; the Earth at 2017 Mar 20, relative to the J2000
;; reference frame.
;;
cspice_str2et, '2017 Mar 20', et
cspice_spkpos, 'Moon', et, 'J2000', 'NONE', 'Earth', pos, ltime
;;
;; Convert the position vector `pos' to cylindrical
;; coordinates.
;;
cspice_reccyl, pos, r, clon, z
;;
;; Convert the cylindrical to rectangular coordinates.
;;
cspice_cylrec, r, clon, z, rectan
print, ' '
print, 'Original rectangular coordinates:'
print, ' '
print, format='(A,F20.8)', ' X (km): ', pos[0]
print, format='(A,F20.8)', ' Y (km): ', pos[1]
print, format='(A,F20.8)', ' Z (km): ', pos[2]
print, ' '
print, 'Cylindrical coordinates:'
print, ' '
print, format='(A,F20.8)', ' Radius (km): ', r
print, format='(A,F20.8)', ' Longitude (deg): ', clon*cspice_dpr( )
print, format='(A,F20.8)', ' Z (km): ', z
print, ' '
print, 'Rectangular coordinates from cspice_cylrec:'
print, ' '
print, format='(A,F20.8)', ' X (km): ', rectan[0]
print, format='(A,F20.8)', ' Y (km): ', rectan[1]
print, format='(A,F20.8)', ' Z (km): ', rectan[2]
print, ' '
END
When this program was executed on a Mac/Intel/IDL8.x/64-bit
platform, the output was:
Original rectangular coordinates:
X (km): -55658.44323296
Y (km): -379226.32931475
Z (km): -126505.93063865
Cylindrical coordinates:
Radius (km): 383289.01777726
Longitude (deg): 261.65040211
Z (km): -126505.93063865
Rectangular coordinates from cspice_cylrec:
X (km): -55658.44323296
Y (km): -379226.32931475
Z (km): -126505.93063865
2) Create a table showing a variety of rectangular coordinates
and the corresponding cylindrical coordinates.
Corresponding rectangular and cylindrical coordinates are
listed to three decimal places. Output angles are in degrees.
Example code begins here.
PRO reccyl_ex2
;;
;; Local parameters.
;;
NREC = 11
;;
;; Define the input rectangular coordinates.
;;
rectan = [[ 0.0d, 0.0d, 0.0d], $
[ 1.0d, 0.0d, 0.0d], $
[ 0.0d, 1.0d, 0.0d], $
[ 0.0d, 0.0d, 1.0d], $
[-1.0d, 0.0d, 0.0d], $
[ 0.0d, -1.0d, 0.0d], $
[ 0.0d, 0.0d, -1.0d], $
[ 1.0d, 1.0d, 0.0d], $
[ 1.0d, 0.0d, 1.0d], $
[ 0.0d, 1.0d, 1.0d], $
[ 1.0d, 1.0d, 1.0d]]
;;
;; Print the banner.
;;
print, ' rect[0] rect[1] rect[2] r clon z'
print, ' ------- ------- ------- ------- ------- -------'
;;
;; Do the conversion. Output angles in degrees.
;;
for i=0, NREC - 1L do begin
cspice_reccyl, rectan[*,i], r, clon, z
print, format='(3F9.3,$)', rectan[*,i]
print, format='(3F9.3)', r, clon * cspice_dpr( ), z
endfor
END
When this program was executed on a Mac/Intel/IDL8.x/64-bit
platform, the output was:
rect[0] rect[1] rect[2] r clon z
------- ------- ------- ------- ------- -------
0.000 0.000 0.000 0.000 0.000 0.000
1.000 0.000 0.000 1.000 0.000 0.000
0.000 1.000 0.000 1.000 90.000 0.000
0.000 0.000 1.000 0.000 0.000 1.000
-1.000 0.000 0.000 1.000 180.000 0.000
0.000 -1.000 0.000 1.000 270.000 0.000
0.000 0.000 -1.000 0.000 0.000 -1.000
1.000 1.000 0.000 1.414 45.000 0.000
1.000 0.000 1.000 1.000 0.000 1.000
0.000 1.000 1.000 1.000 90.000 1.000
1.000 1.000 1.000 1.414 45.000 1.000
This routine transforms the coordinates of a point from
rectangular to cylindrical coordinates.
1) If the input argument `rectan' is undefined, an error is
signaled by the IDL error handling system.
2) If the input argument `rectan' is not of the expected type, or
it does not have the expected dimensions and size, an error is
signaled by the Icy interface.
3) If any of the output arguments, `r', `clon' or `z', is not a
named variable, an error is signaled by the Icy interface.
None.
None.
ICY.REQ
None.
J. Diaz del Rio (ODC Space)
E.D. Wright (JPL)
-Icy Version 1.2.0, 17-AUG-2021 (JDR)
Edited the -Examples section to comply with NAIF standard.
Added complete code examples.
Changed the output argument name "lon" to "clon" for consistency
with other routines.
Added -Parameters, -Exceptions, -Files, -Restrictions,
-Literature_References and -Author_and_Institution sections, and
completed -Particulars section.
Removed reference to the routine's corresponding CSPICE header from
-Abstract section.
Added arguments' type and size information in the -I/O section.
-Icy Version 1.1.2, 29-SEP-2007 (EDW)
Replaced the fragment
"return with the same order"
with
"return with the same measure of vectorization"
-Icy Version 1.1.1, 09-DEC-2005 (EDW)
Added -Examples section.
-Icy Version 1.1.0, 12-SEP-2004 (EDW)
Added capability to process vector 'rectan' as
input returning vectors 'r', 'clon', and 'z'
on output.
-Icy Version 1.0.0, 16-JUN-2003 (EDW)
rectangular to cylindrical coordinates
|