Table of contents
CSPICE_SPHCYL converts spherical coordinates to cylindrical
coordinates.
Given:
radius the scalar double precision distance of the point from origin.
help, radius
DOUBLE = Scalar
colat the scalar double precision polar angle (co-latitude) of the
point measured in radians.
help, colat
DOUBLE = Scalar
slon the scalar double precision azimuthal angle (longitude) of the
point measured in radians.
help, slon
DOUBLE = Scalar
the call:
cspice_sphcyl, radius, colat, slon, r, clon, z
returns the values:
r the scalar double precision value for distance of the point from
Z-axis.
help, r
DOUBLE = Scalar
clon the scalar double precision value for the cylindrical angle of
the point from XZ plane as measured in radians.
help, clon
DOUBLE = Scalar
z the scalar double precision value for the height of the point
above XY plane.
help, z
DOUBLE = Scalar
None.
Any numerical results shown for these examples may differ between
platforms as the results depend on the SPICE kernels used as input
and the machine specific arithmetic implementation.
1) Compute the spherical coordinates of the position of the Moon
as seen from the Earth, and convert them to cylindrical and
rectangular coordinates.
Use the meta-kernel shown below to load the required SPICE
kernels.
KPL/MK
File name: sphcyl_ex1.tm
This meta-kernel is intended to support operation of SPICE
example programs. The kernels shown here should not be
assumed to contain adequate or correct versions of data
required by SPICE-based user applications.
In order for an application to use this meta-kernel, the
kernels referenced here must be present in the user's
current working directory.
The names and contents of the kernels referenced
by this meta-kernel are as follows:
File name Contents
--------- --------
de421.bsp Planetary ephemeris
naif0012.tls Leapseconds
\begindata
KERNELS_TO_LOAD = ( 'de421.bsp',
'naif0012.tls' )
\begintext
End of meta-kernel
Example code begins here.
PRO sphcyl_ex1
;;
;; Load SPK and LSK kernels, use a meta kernel for
;; convenience.
;;
cspice_furnsh, 'sphcyl_ex1.tm'
;;
;; Look up the geometric state of the Moon as seen from
;; the Earth at 2017 Mar 20, relative to the J2000
;; reference frame.
;;
cspice_str2et, '2017 Mar 20', et
cspice_spkpos, 'Moon', et, 'J2000', 'NONE', 'Earth', pos, ltime
;;
;; Convert the position vector `pos' to spherical
;; coordinates.
;;
cspice_recsph, pos, radius, colat, slon
;;
;; Convert the spherical coordinates to cylindrical.
;;
cspice_sphcyl, radius, colat, slon, r, clon, z
;;
;; Convert the cylindrical coordinates to rectangular.
;;
cspice_cylrec, r, clon, z, rectan
print, ' '
print, 'Original rectangular coordinates:'
print, ' '
print, format='(A,F20.8)', ' X (km): ', pos[0]
print, format='(A,F20.8)', ' Y (km): ', pos[1]
print, format='(A,F20.8)', ' Z (km): ', pos[2]
print, ' '
print, 'Spherical coordinates:'
print, ' '
print, format='(A,F20.8)', ' Radius (km): ', radius
print, format='(A,F20.8)', ' Colatitude (deg): ', $
colat*cspice_dpr( )
print, format='(A,F20.8)', ' Longitude (deg): ', $
slon*cspice_dpr( )
print, ' '
print, 'Cylindrical coordinates:'
print, ' '
print, format='(A,F20.8)', ' Radius (km): ', r
print, format='(A,F20.8)', ' Longitude (deg): ', $
clon*cspice_dpr( )
print, format='(A,F20.8)', ' Z (km): ', z
print, ' '
print, 'Rectangular coordinates from cspice_cylrec:'
print, ' '
print, format='(A,F20.8)', ' X (km): ', rectan[0]
print, format='(A,F20.8)', ' Y (km): ', rectan[1]
print, format='(A,F20.8)', ' Z (km): ', rectan[2]
print, ' '
END
When this program was executed on a Mac/Intel/IDL8.x/64-bit
platform, the output was:
Original rectangular coordinates:
X (km): -55658.44323296
Y (km): -379226.32931475
Z (km): -126505.93063865
Spherical coordinates:
Radius (km): 403626.33912495
Colatitude (deg): 108.26566077
Longitude (deg): -98.34959789
Cylindrical coordinates:
Radius (km): 383289.01777726
Longitude (deg): -98.34959789
Z (km): -126505.93063865
Rectangular coordinates from cspice_cylrec:
X (km): -55658.44323296
Y (km): -379226.32931475
Z (km): -126505.93063865
2) Create a table showing a variety of spherical coordinates
and the corresponding cylindrical coordinates.
Corresponding spherical and cylindrical coordinates are
listed to three decimal places. Input and output angles are
in degrees.
Example code begins here.
PRO sphcyl_ex2
;;
;; Local parameters.
;;
NREC = 11
;;
;; Define the input spherical coordinates. Angles in degrees.
;;
radius = [ 0.0d, 1.0d, 1.0d, 1.0d, 1.4142d, 1.0d, $
1.0d, 1.0d, 1.4142d, 1.0d, 0.0d ]
colat = [ 0.0d, 90.0d, 90.0d, 0.0d, 45.0d, 90.0d, $
180.0d, 90.0d, 135.0d, 0.0d, 90.0d ]
slon = [ 0.0d, 0.0d, 90.0d, 0.0d, 180.0d, -90.0d, $
0.0d, 45.0d, 180.0d, 180.0d, 33.0d ]
;;
;; Print the banner.
;;
print, ' radius colat slon r clon z'
print, ' ------- ------- ------- ------- ------- -------'
;;
;; Do the conversion. Output angles in degrees.
;;
for i=0, NREC - 1L do begin
rcolat = colat[i] * cspice_rpd( )
rslon = slon[i] * cspice_rpd( )
cspice_sphcyl, radius[i], rcolat, rslon, r, clon, z
print, format='(3F9.3,$)', radius[i], colat[i], slon[i]
print, format='(3F9.3)', r, clon * cspice_dpr( ), z
endfor
END
When this program was executed on a Mac/Intel/IDL8.x/64-bit
platform, the output was:
radius colat slon r clon z
------- ------- ------- ------- ------- -------
0.000 0.000 0.000 0.000 0.000 0.000
1.000 90.000 0.000 1.000 0.000 0.000
1.000 90.000 90.000 1.000 90.000 0.000
1.000 0.000 0.000 0.000 0.000 1.000
1.414 45.000 180.000 1.000 180.000 1.000
1.000 90.000 -90.000 1.000 -90.000 0.000
1.000 180.000 0.000 0.000 0.000 -1.000
1.000 90.000 45.000 1.000 45.000 0.000
1.414 135.000 180.000 1.000 180.000 -1.000
1.000 0.000 180.000 0.000 180.000 1.000
0.000 90.000 33.000 0.000 33.000 0.000
3) Other than the obvious conversion between coordinate systems
this routine could be used to obtain the axial projection
from a sphere to a cylinder about the z-axis that contains
the equator of the sphere.
Such a projection is valuable because it preserves the
areas between regions on the sphere and their projections to
the cylinder.
Example code begins here.
PRO sphcyl_ex3
;;
;; Define the point whose projection is to be
;; computed.
;;
radius = 100.0
slon = 45.0 * cspice_rpd()
colat = 102.5 * cspice_rpd()
;;
;; Convert the spherical coordinates to cylindrical.
;;
cspice_sphcyl, radius, colat, slon, r, clon, z
print, 'Coordinates of the projected point on cylinder:'
print, ' '
print, format='(A,F23.11)', ' Radius (km): ', r
print, format='(A,F23.11)', ' Longitude (deg): ', clon*cspice_dpr()
print, format='(A,F23.11)', ' Z (km): ', z
END
When this program was executed on a Mac/Intel/IDL8.x/64-bit
platform, the output was:
Coordinates of the projected point on cylinder:
Radius (km): 97.62960071199
Longitude (deg): 45.00000000000
Z (km): -21.64396139381
This returns the cylindrical coordinates of a point whose
position is input through spherical coordinates.
1) If any of the input arguments, `radius', `colat' or `slon', is
undefined, an error is signaled by the IDL error handling
system.
2) If any of the input arguments, `radius', `colat' or `slon', is
not of the expected type, or it does not have the expected
dimensions and size, an error is signaled by the Icy
interface.
3) If any of the output arguments, `r', `clon' or `z', is not a
named variable, an error is signaled by the Icy interface.
None.
None.
ICY.REQ
None.
J. Diaz del Rio (ODC Space)
E.D. Wright (JPL)
-Icy Version 1.1.0, 10-AUG-2021 (JDR)
Edited the -Examples section to comply with NAIF standard.
Added complete code examples.
Changed the input argument name "lonc" to "clon" for consistency
with other routines.
Added -Parameters, -Exceptions, -Files, -Restrictions,
-Literature_References and -Author_and_Institution sections, and
completed -Particulars section.
Removed reference to the routine's corresponding CSPICE header from
-Abstract section.
Added arguments' type and size information in the -I/O section.
-Icy Version 1.0.1, 09-DEC-2005 (EDW)
Added -Examples section.
-Icy Version 1.0.0, 16-JUN-2003 (EDW)
spherical to cylindrical coordinates
|