Table of contents
CSPICE_RECSPH converts rectangular (Cartesian) coordinates to
spherical coordinates. All coordinates are expressed as
double precision values.
Given:
rectan the rectangular coordinate of points, or an N-vector of
coordinates.
help, rectan
DOUBLE = Array[3] or DOUBLE = Array[3,N]
the call:
cspice_recsph, rectan, r, colat, slon
returns:
r the distance of the point from the origin, or an N-vector of
distances.
help, r
DOUBLE = Scalar or DOUBLE = Array[N]
colat the angle between the point and the positive Z-axis, or an
N-vector of angles, in radians.
help, colat
DOUBLE = Scalar or DOUBLE = Array[N]
The range of `colat' is [0, pi].
slon the longitude of the point, or an N-vector of longitudes, in
radians.
help, slon
DOUBLE = Scalar or DOUBLE = Array[N]
This is the angle between the positive X-axis and the
orthogonal projection of the point onto the XY plane. `slon'
increases in the counterclockwise sense about the positive
Z-axis. The range of `slon' is [-pi, pi].
`r', `colat', and `slon' return with the same measure of
vectorization (N) as `rectan'.
None.
Any numerical results shown for these examples may differ between
platforms as the results depend on the SPICE kernels used as input
and the machine specific arithmetic implementation.
1) Compute the spherical coordinates of the position of the Moon
as seen from the Earth, and convert them to rectangular
coordinates.
Use the meta-kernel shown below to load the required SPICE
kernels.
KPL/MK
File name: recsph_ex1.tm
This meta-kernel is intended to support operation of SPICE
example programs. The kernels shown here should not be
assumed to contain adequate or correct versions of data
required by SPICE-based user applications.
In order for an application to use this meta-kernel, the
kernels referenced here must be present in the user's
current working directory.
The names and contents of the kernels referenced
by this meta-kernel are as follows:
File name Contents
--------- --------
de421.bsp Planetary ephemeris
naif0012.tls Leapseconds
\begindata
KERNELS_TO_LOAD = ( 'de421.bsp',
'naif0012.tls' )
\begintext
End of meta-kernel
Example code begins here.
PRO recsph_ex1
;;
;; Load SPK and LSK kernels, use a meta kernel for
;; convenience.
;;
cspice_furnsh, 'recsph_ex1.tm'
;;
;; Look up the geometric state of the Moon as seen from
;; the Earth at 2017 Mar 20, relative to the J2000
;; reference frame.
;;
cspice_str2et, '2017 Mar 20', et
cspice_spkpos, 'Moon', et, 'J2000', 'NONE', 'Earth', pos, ltime
;;
;; Convert the position vector `pos' to spherical
;; coordinates.
;;
cspice_recsph, pos, radius, colat, slon
;;
;; Convert the spherical coordinates to rectangular.
;;
cspice_sphrec, radius, colat, slon, rectan
print, ' '
print, 'Original rectangular coordinates:'
print, ' '
print, format='(A,F20.8)', ' X (km): ', pos[0]
print, format='(A,F20.8)', ' Y (km): ', pos[1]
print, format='(A,F20.8)', ' Z (km): ', pos[2]
print, ' '
print, 'Spherical coordinates:'
print, ' '
print, format='(A,F20.8)', ' Radius (km): ', radius
print, format='(A,F20.8)', ' Colatitude (deg): ', $
colat*cspice_dpr( )
print, format='(A,F20.8)', ' Longitude (deg): ', $
slon*cspice_dpr( )
print, ' '
print, 'Rectangular coordinates from cspice_sphrec:'
print, ' '
print, format='(A,F20.8)', ' X (km): ', rectan[0]
print, format='(A,F20.8)', ' Y (km): ', rectan[1]
print, format='(A,F20.8)', ' Z (km): ', rectan[2]
print, ' '
END
When this program was executed on a Mac/Intel/IDL8.x/64-bit
platform, the output was:
Original rectangular coordinates:
X (km): -55658.44323296
Y (km): -379226.32931475
Z (km): -126505.93063865
Spherical coordinates:
Radius (km): 403626.33912495
Colatitude (deg): 108.26566077
Longitude (deg): -98.34959789
Rectangular coordinates from cspice_sphrec:
X (km): -55658.44323296
Y (km): -379226.32931475
Z (km): -126505.93063865
2) Create a table showing a variety of rectangular coordinates
and the corresponding spherical coordinates.
Corresponding rectangular and spherical coordinates are
listed to three decimal places. Output angles are in degrees.
Example code begins here.
PRO recsph_ex2
;;
;; Local parameters.
;;
NREC = 11
;;
;; Define the input rectangular coordinates.
;;
rectan = [[ 0.0d, 0.0d, 0.0d], $
[ 1.0d, 0.0d, 0.0d], $
[ 0.0d, 1.0d, 0.0d], $
[ 0.0d, 0.0d, 1.0d], $
[-1.0d, 0.0d, 0.0d], $
[ 0.0d, -1.0d, 0.0d], $
[ 0.0d, 0.0d, -1.0d], $
[ 1.0d, 1.0d, 0.0d], $
[ 1.0d, 0.0d, 1.0d], $
[ 0.0d, 1.0d, 1.0d], $
[ 1.0d, 1.0d, 1.0d]]
;;
;; Print the banner.
;;
print, ' rect[0] rect[1] rect[2] radius colat slon'
print, ' ------- ------- ------- ------- ------- -------'
;;
;; Do the conversion. Output angles in degrees.
;;
for i=0, NREC - 1L do begin
cspice_recsph, rectan[*,i], radius, colat, slon
print, format='(3F9.3,$)', rectan[*,i]
print, format='(F8.3,2F9.3)', radius, colat * cspice_dpr(), $
slon * cspice_dpr()
endfor
END
When this program was executed on a Mac/Intel/IDL8.x/64-bit
platform, the output was:
rect[0] rect[1] rect[2] radius colat slon
------- ------- ------- ------- ------- -------
0.000 0.000 0.000 0.000 0.000 0.000
1.000 0.000 0.000 1.000 90.000 0.000
0.000 1.000 0.000 1.000 90.000 90.000
0.000 0.000 1.000 1.000 0.000 0.000
-1.000 0.000 0.000 1.000 90.000 180.000
0.000 -1.000 0.000 1.000 90.000 -90.000
0.000 0.000 -1.000 1.000 180.000 0.000
1.000 1.000 0.000 1.414 90.000 45.000
1.000 0.000 1.000 1.414 45.000 0.000
0.000 1.000 1.000 1.414 45.000 90.000
1.000 1.000 1.000 1.732 54.736 45.000
This routine returns the spherical coordinates of a point
whose position is input in rectangular coordinates.
Spherical coordinates are defined by a distance from a central
reference point, an angle from a reference meridian, and an angle
from the Z-axis.
1) If the input argument `rectan' is undefined, an error is
signaled by the IDL error handling system.
2) If the input argument `rectan' is not of the expected type, or
it does not have the expected dimensions and size, an error is
signaled by the Icy interface.
3) If any of the output arguments, `r', `colat' or `slon', is not
a named variable, an error is signaled by the Icy interface.
None.
None.
ICY.REQ
None.
J. Diaz del Rio (ODC Space)
E.D. Wright (JPL)
-Icy Version 1.2.0, 13-AUG-2021 (JDR)
Edited the -Examples section to comply with NAIF standard.
Added complete code examples.
Changed the output argument name "lon" to "slon" for consistency
with other routines.
Added -Parameters, -Exceptions, -Files, -Restrictions,
-Literature_References and -Author_and_Institution sections, and
completed -Particulars section.
Removed reference to the routine's corresponding CSPICE header from
-Abstract section.
Added arguments' type and size information in the -I/O section.
-Icy Version 1.1.3, 29-SEP-2007 (EDW)
Replaced the comment fragment in the -I/O section
"return with the same order"
with
"return with the same measure of vectorization"
-Icy Version 1.1.2, 09-DEC-2005 (EDW)
Added -Examples section.
-Icy Version 1.1.0, 12-SEP-2004 (EDW)
Added capability to process vector 'rectan' as
input returning vectors 'r', 'colat', and 'slon'
on output.
-Icy Version 1.0.0, 16-JUN-2003 (EDW)
rectangular to spherical coordinates
|