Table of contents
CSPICE_PCKFRM finds the set of reference frame class ID codes of all
frames in a specified binary PCK file.
Given:
pckfnm the name of a binary PCK file.
help, pckfnm
STRING = Scalar
ids an initialized SPICE set data structure.
help, ids
STRUCT = cspice_celli(N)
`ids' optionally may contain a set of ID codes on input; on
output, the data already present in `ids' will be combined with
ID code set found for the file `pckfnm'.
If `ids' contains no data on input, its size and
cardinality still must be initialized.
the call:
cspice_pckfrm, pckfnm, ids
returns:
ids a SPICE set data structure which contains the union of its
contents upon input with the set of reference frame class ID
codes of each frame for which data are present in the indicated
PCK file.
help, ids
STRUCT = cspice_celli(N)
The elements of SPICE sets are unique; hence each ID code in
`ids' appears only once, even if the PCK file contains multiple
segments for that ID code.
See the -Examples section below for a complete example
program showing how to retrieve the ID codes from `ids'.
The user must create `ids' using cspice_celli. (Note:
a set is a type of cell).
None.
Any numerical results shown for this example may differ between
platforms as the results depend on the SPICE kernels used as input
and the machine specific arithmetic implementation.
1) Use a simple routine to display the coverage for each object in a
specified PCK file(s). Find the set of objects in the file(s); for
each object, find and display the coverage.
Use the LSK kernel below to load the leap seconds and time
constants required for the time conversions.
naif0012.tls
Example code begins here.
PRO pckfrm_ex1, pcknam
;;
;; From a given PCK file, retrieve the list of objects listed
;; in the file then retrieve the time coverage for each object.
;;
;; Local parameters...
;;
MAXIV = 1000
WINSIZ = 2 * MAXIV
TIMLEN = 51
MAXOBJ = 1000
LSK = 'naif0012.tls';
;;
;; Local variables
;;
cover = cspice_celld( WINSIZ )
ids = cspice_celli( MAXOBJ )
;;
;; Note, neither cspice_pckcov or cspice_pckfrm requires this
;; kernel to function. We need the data for output time
;; conversion.
;;
cspice_furnsh, LSK
;;
;; Find the set of frames in the PCK file.
;;
for i = 1, n_elements(pcknam) do begin
cspice_pckfrm, pcknam[i-1], ids
endfor
;;
;; We want to display the coverage for each frame. Loop over
;; the contents of the ID code set, find the coverage for
;; each item in the set, and display the coverage.
;;
for i=0, cspice_card( ids ) - 1 do begin
;;
;; Find the coverage window for the current frame, 'i'.
;; Empty the coverage window each time
;; so we don't include data for the previous object.
;;
obj = ids.base[ ids.data + i ]
cspice_scard, 0L, cover
for k = 1, n_elements(pcknam) do begin
cspice_pckcov, pcknam[k-1], obj, cover
endfor
;;
;; Get the number of intervals in the coverage window.
;;
niv = cspice_card( cover ) / 2
;;
;; Display a simple banner.
;;
print, "========================================"
print, "Coverage for frame:", obj
;;
;; Convert the coverage interval start and stop times to TDB
;; calendar strings.
;;
for j=0, niv-1 do begin
;;
;; Get the endpoints of the jth interval.
;;
cspice_wnfetd, cover, j, b, e
;;
;; Convert the endpoints to TDB calendar
;; format time strings and display them.
;; Pass the endpoints in an array, [b,e],
;; so cspice_timout returns an array of time
;; strings.
;;
cspice_timout, [b,e], $
"YYYY MON DD HR:MN:SC.### (TDB) ::TDB", $
TIMLEN ,$
timstr
print, "Interval: ", j
print, "Start : ", timstr[0]
print, "Stop : ", timstr[1]
print
endfor
endfor
;;
;; Empty the kernel pool.
;;
cspice_kclear
END
When this program was executed on a Mac/Intel/IDL8.x/64-bit
platform, with the following variable as input
pcknam = [ 'earth_720101_070426.bpc', 'moon_pa_de421_1900-2050.bpc' ]
the output was:
========================================
Coverage for frame: 3000
Interval: 0
Start : 1962 JAN 20 00:00:41.184 (TDB)
Stop : 2007 APR 26 00:01:05.185 (TDB)
========================================
Coverage for frame: 31006
Interval: 0
Start : 1900 JAN 01 00:00:00.000 (TDB)
Stop : 2051 JAN 01 00:00:00.000 (TDB)
This routine provides an API via which applications can determine
the set of reference frames for which there are data in a
specified PCK file.
1) If the input file has transfer format, the error
SPICE(INVALIDFORMAT) is signaled by a routine in the call tree
of this routine.
2) If the input file is not a transfer file but has architecture
other than DAF, the error SPICE(INVALIDARCHTYPE) is signaled
by a routine in the call tree of this routine.
3) If the input file is a binary DAF file of type other than PCK,
the error SPICE(INVALIDFILETYPE) is signaled by a routine in
the call tree of this routine.
4) If the PCK file cannot be opened or read, an error is signaled
by a routine in the call tree of this routine.
5) If the size of the output set argument `ids' is insufficient to
contain the actual number of ID codes of frames covered by the
indicated PCK file, an error is signaled by a routine in the
call tree of this routine.
6) If any of the input arguments, `pckfnm' or `ids', is
undefined, an error is signaled by the IDL error handling
system.
7) If any of the input arguments, `pckfnm' or `ids', is not of
the expected type, or it does not have the expected dimensions
and size, an error is signaled by the Icy interface.
None.
1) If an error occurs while this routine is updating the set
`ids', the set may be corrupted.
CELLS.REQ
DAF.REQ
ICY.REQ
PCK.REQ
SETS.REQ
None.
J. Diaz del Rio (ODC Space)
M. Liukis (JPL)
E.D. Wright (JPL)
-Icy Version 1.1.0, 24-AUG-2021 (JDR)
Changed the input argument name "pck" to "pckfnm" for consistency
with other routines.
Edited the header to comply with NAIF standard.
Added -Parameters, -Exceptions, -Files, -Restrictions,
-Literature_References and -Author_and_Institution sections.
Removed reference to the routine's corresponding CSPICE header from
-Abstract section.
Added arguments' type and size information in the -I/O section.
-Icy Version 1.0.0, 04-JAN-2017 (ML) (EDW)
find frame class id codes of frames in binary PCK file
|