Table of contents
CSPICE_EKFFLD completes a fast write operation on a
new EK data segment.
Given:
handle the scalar integer referring to an EK file open for write
access.
help, handle
LONG = Scalar
segno the scalar integer value for the data segment targeted by the
data write.
help, segno
LONG = Scalar
rcptrs an array of integers holding the record pointers for the input
segment.
help, rcptrs
LONG = Array[N]
the call:
cspice_ekffld, handle, segno, rcptrs
finishes the segment `segno' in the EK file referred to by `handle'.
None.
Any numerical results shown for this example may differ between
platforms as the results depend on the SPICE kernels used as input
and the machine specific arithmetic implementation.
1) Suppose we want to create an Sequence Component E-kernel
named 'ekffld_ex1.bdb' which contains records of orders for
data products. The E-kernel has a table called DATAORDERS
that consists of the set of columns listed below:
DATAORDERS
Column Name Data Type
----------- ---------
ORDER_ID INTEGER
CUSTOMER_ID INTEGER
LAST_NAME CHARACTER*(*)
FIRST_NAME CHARACTER*(*)
ORDER_DATE TIME
COST DOUBLE PRECISION
The order database also has a table of items that have been
ordered. The columns of this table are shown below:
DATAITEMS
Column Name Data Type
----------- ---------
ITEM_ID INTEGER
ORDER_ID INTEGER
ITEM_NAME CHARACTER*(*)
DESCRIPTION CHARACTER*(*)
PRICE DOUBLE PRECISION
The file 'ekffld_ex1.bdb' will contain two segments, the first
containing the DATAORDERS table and the second containing the
DATAITEMS table.
This example demonstrates how to open a new EK file and create
the first of the segments described above.
Use the LSK kernel below to load the leap seconds and time
constants required for the conversions.
naif0012.tls
Example code begins here.
PRO ekffld_ex1
;;
;; Initialize needed parameters.
;;
SPICEFALSE = 0B
SPICETRUE = 1B
EKNAME = 'ekffld_ex1.bdb'
FNMLEN = 50
IFNAME = 'Test EK'
LNMLEN = 50
LSK = 'naif0012.tls'
NCOLS = 6
NRESVC = 0
NROWS = 9
TABLE = 'DATAORDERS'
;;
;; Load a leapseconds kernel for UTC/ET conversion.
;;
cspice_furnsh, LSK
;;
;; Open a new EK file. For simplicity, we won't
;; reserve space for the comment area, so the
;; number of reserved comment characters is zero.
;; The constant IFNAME is the internal file name.
;;
cspice_ekopn, EKNAME, IFNAME, NRESVC, handle
cnames = strarr( NCOLS )
cdecls = strarr( NCOLS )
cnames[0] = 'ORDER_ID'
cdecls[0] = 'DATATYPE = INTEGER, INDEXED = TRUE'
cnames[1] = 'CUSTOMER_ID'
cdecls[1] = 'DATATYPE = INTEGER, INDEXED = TRUE'
cnames[2] = 'LAST_NAME'
cdecls[2] = 'DATATYPE = CHARACTER*(*), INDEXED = TRUE'
cnames[3] = 'FIRST_NAME'
cdecls[3] = 'DATATYPE = CHARACTER*(*), INDEXED = TRUE'
cnames[4] = 'ORDER_DATE'
cdecls[4] = 'DATATYPE = TIME, INDEXED = TRUE'
cnames[5] = 'COST'
cdecls[5] = 'DATATYPE = DOUBLE PRECISION, ' + $
'INDEXED = TRUE, NULLS_OK = TRUE'
;;
;; Start the segment. We presume the number of rows
;; of data is known in advance.
;;
cspice_ekifld, handle, TABLE, NCOLS, NROWS, $
cnames, cdecls, segno, rcptrs
;;
;; At this point, arrays containing data for the
;; segment's columns may be filled in. The names
;; of the data arrays are shown below.
;;
;; Column Data array
;;
;; 'ORDER_ID' ordids
;; 'CUSTOMER_ID' cstids
;; 'LAST_NAME' lnames
;; 'FIRST_NAME' fnames
;; 'ORDER_DATE' ets
;; 'COST' costs
;;
;;
;; The null flags array indicates which entries are null.
;; It is ignored for columns that don't allow null
;; values. In this case, only the COST column allows
;; nulls.
;;
;; Fill in data arrays and null flag arrays here. This code
;; section would normally be replaced by calls to user functions
;; returning column values.
;;
ordids = lonarr( NROWS)
cstids = lonarr( NROWS)
costs = dblarr( NROWS)
ets = dblarr( NROWS)
fnames = strarr( NROWS)
lnames = strarr( NROWS)
nlflgs = lonarr( NROWS)
wkindx = lonarr( NROWS)
sizes = lonarr( NROWS)
for i = 0, (NROWS-1) do begin
ordids[i] = i
cstids[i] = i*100
costs [i] = double(100*i)
fnames[i] = 'Order ' + string(i) + ' Customer first name'
lnames[i] = 'Order ' + string(i) + ' Customer last name'
date_string = '2001 Mar ' + string(i)
cspice_utc2et, date_string, et
ets[i] = et
nlflgs[i] = SPICEFALSE
endfor
nlflgs[1] = SPICETRUE
;;
;; The sizes array shown below is ignored for scalar
;; and fixed-size array columns, so we need not
;; initialize it. For variable-size arrays, the
;; Ith element of the sizes array must contain the size
;; of the Ith column entry in the column being written.
;; Normally, the sizes array would be reset for each
;; variable-size column.
;;
;; Add the columns of data to the segment. All of the
;; data for each column is written in one shot.
;;
cspice_ekacli, handle, segno , 'order_id', ordids, sizes, $
nlflgs, rcptrs, wkindx
cspice_ekacli, handle, segno , 'customer_id', cstids, sizes, $
nlflgs, rcptrs, wkindx
cspice_ekaclc, handle, segno , 'last_name', LNMLEN, lnames, $
sizes , nlflgs, rcptrs , wkindx
cspice_ekaclc, handle, segno, 'first_name', FNMLEN, fnames, $
sizes, nlflgs , rcptrs, wkindx
cspice_ekacld, handle, segno , 'order_date', ets, sizes, $
nlflgs, rcptrs, wkindx
cspice_ekacld, handle, segno , 'cost', costs, sizes, $
nlflgs, rcptrs, wkindx
;;
;; Complete the segment. The rcptrs array is that
;; returned by ekifld_c.
;;
cspice_ekffld, handle, segno, rcptrs
;;
;; The file must be closed by a call to cspice_ekcls
;;
cspice_ekcls, handle
cspice_unload, LSK
END
When this program is executed, no output is presented on
screen. After run completion, a new EK file exists in the
output directory.
This routine completes an EK segment after the data has been
written via the fast column writer routines. The segment must
have been created by a call to cspice_ekifld. The fast column
writer routines are:
cspice_ekaclc {EK, add column, character}
cspice_ekacld {EK, add column, double precision}
cspice_ekacli {EK, add column, integer}
The segment is not guaranteed to be readable until all columns
have been added. After the columns have been added, the segment
may be extended by inserting more records and filling in those
records using the cspice_ekaceX routines.
An EK initialized with cspice_ekifld must end the segment
write with cspice_ekffld before closing the EK with a call to
cspice_ekcls.
1) If `handle' is invalid, an error is signaled by a routine in the
call tree of this routine.
2) If an attempt is made to finish a segment other than the one
last initialized by cspice_ekifld, an error is signaled by a routine
in the call tree of this routine.
3) If an i/o error occurs while reading or writing the indicated
file, the error is signaled by a routine in the call tree of
this routine.
4) If any of the input arguments, `handle', `segno' or `rcptrs',
is undefined, an error is signaled by the IDL error handling
system.
5) If any of the input arguments, `handle', `segno' or `rcptrs',
is not of the expected type, or it does not have the expected
dimensions and size, an error is signaled by the Icy
interface.
See the EK Required Reading ek.req for a discussion of the EK file
format.
1) Only one segment can be created at a time using the fast
write routines.
2) No other EK operation may interrupt a fast write. For
example, it is not valid to issue a query while a fast write
is in progress.
ICY.REQ
EK.REQ
None.
J. Diaz del Rio (ODC Space)
E.D. Wright (JPL)
-Icy Version 1.0.1, 24-NOV-2021 (JDR)
Edited the header to comply with NAIF standard.
Added -Parameters, -Exceptions, -Files, -Restrictions,
-Literature_References and -Author_and_Institution sections, and
completed -Particulars section.
Removed reference to the routine's corresponding CSPICE header from
-Abstract section.
Added arguments' type and size information in the -I/O section.
-Icy Version 1.0.0, 16-JUN-2003 (EDW)
finish a fast EK segment write
|