Table of contents
CSPICE_CYLLAT converts cylindrical coordinates to latitudinal
coordinates.
Given:
r the distance of the input point from Z axis.
help, r
DOUBLE = Scalar
clon the cylindrical angle of the point from XZ plane (radians).
help, clon
DOUBLE = Scalar
z the height of the point above XY plane.
help, z
DOUBLE = Scalar
the call:
cspice_cyllat, r, clon, z, radius, lon, lat
returns:
radius the distance of the input point from origin.
help, radius
DOUBLE = Scalar
lon the longitude (i.e. angle from the XZ plane) of the input point
(radians).
help, lon
DOUBLE = Scalar
`lon' is set equal to `clon'.
lat the latitude (i.e. angle above the XY plane) of the input point
(radians).
help, lat
DOUBLE = Scalar
The range of `lat' is [-pi, pi].
None.
Any numerical results shown for these examples may differ between
platforms as the results depend on the SPICE kernels used as input
and the machine specific arithmetic implementation.
1) Compute the cylindrical coordinates of the position of the
Moon as seen from the Earth, and convert them to latitudinal
and rectangular coordinates.
Use the meta-kernel shown below to load the required SPICE
kernels.
KPL/MK
File name: cyllat_ex1.tm
This meta-kernel is intended to support operation of SPICE
example programs. The kernels shown here should not be
assumed to contain adequate or correct versions of data
required by SPICE-based user applications.
In order for an application to use this meta-kernel, the
kernels referenced here must be present in the user's
current working directory.
The names and contents of the kernels referenced
by this meta-kernel are as follows:
File name Contents
--------- --------
de421.bsp Planetary ephemeris
naif0012.tls Leapseconds
\begindata
KERNELS_TO_LOAD = ( 'de421.bsp',
'naif0012.tls' )
\begintext
End of meta-kernel
Example code begins here.
PRO cyllat_ex1
;;
;; Load SPK and LSK kernels, use a meta kernel for
;; convenience.
;;
cspice_furnsh, 'cyllat_ex1.tm'
;;
;; Look up the geometric state of the Moon as seen from
;; the Earth at 2017 Mar 20, relative to the J2000
;; reference frame.
;;
cspice_str2et, '2017 Mar 20', et
cspice_spkpos, 'Moon', et, 'J2000', 'NONE', 'Earth', pos, ltime
;;
;; Convert the position vector `pos' to cylindrical
;; coordinates.
;;
cspice_reccyl, pos, r, clon, z
;;
;; Convert the cylindrical coordinates to latitudinal.
;;
cspice_cyllat, r, clon, z, radius, lon, lat
;;
;; Convert the latitudinal coordinates to rectangular.
;;
cspice_latrec, radius, lon, lat, rectan
print, ' '
print, 'Original rectangular coordinates:'
print, ' '
print, format='(A,F20.8)', ' X (km): ', pos[0]
print, format='(A,F20.8)', ' Y (km): ', pos[1]
print, format='(A,F20.8)', ' Z (km): ', pos[2]
print, ' '
print, 'Cylindrical coordinates:'
print, ' '
print, format='(A,F20.8)', ' Radius (km): ', r
print, format='(A,F20.8)', ' Longitude (deg): ', clon*cspice_dpr( )
print, format='(A,F20.8)', ' Z (km): ', z
print, ' '
print, 'Latitudinal coordinates:'
print, ' '
print, format='(A,F20.8)', ' Radius (km): ', radius
print, format='(A,F20.8)', ' Longitude (deg): ', lon*cspice_dpr( )
print, format='(A,F20.8)', ' Latitude (deg): ', lat*cspice_dpr( )
print, ' '
print, 'Rectangular coordinates from cspice_latrec:'
print, ' '
print, format='(A,F20.8)', ' X (km): ', rectan[0]
print, format='(A,F20.8)', ' Y (km): ', rectan[1]
print, format='(A,F20.8)', ' Z (km): ', rectan[2]
print, ' '
END
When this program was executed on a Mac/Intel/IDL8.x/64-bit
platform, the output was:
Original rectangular coordinates:
X (km): -55658.44323296
Y (km): -379226.32931475
Z (km): -126505.93063865
Cylindrical coordinates:
Radius (km): 383289.01777726
Longitude (deg): 261.65040211
Z (km): -126505.93063865
Latitudinal coordinates:
Radius (km): 403626.33912495
Longitude (deg): 261.65040211
Latitude (deg): -18.26566077
Rectangular coordinates from cspice_latrec:
X (km): -55658.44323296
Y (km): -379226.32931475
Z (km): -126505.93063865
2) Create a table showing a variety of cylindrical coordinates
and the corresponding latitudinal coordinates.
Corresponding latitudinal and cylindrical coordinates are
listed to three decimal places. All input and output angles
are in degrees.
Example code begins here.
PRO cyllat_ex2
;;
;; Define six sets of cylindrical coordinates, `clon' expressed
;; in degrees.
;;
r = [ 1.d, 1.d, 1.d, 1.d, 0.d, 0.d ]
clon = [ 0.d, 90.d, 180.d, 180.d, 180.d, 33.d ]
z = [ 0.d, 0.d, 1.d, -1.d, 1.d, 0.d ]
;;
;; Print a header for the data output.
;;
print, ' r clon z ', $
' radius lon lat '
print, ' ------- ------- -------', $
' ------- ------- -------'
;;
;; Loop over each set of coordinates...
;;
for i=0, 5 do begin
;;
;; ...convert the `clon' values from degrees to radians
;;
cspice_convrt, clon[i], 'DEGREES', 'RADIANS', clon_rads
;;
;; ..convert the cylindrical coordinates to latitudinal
;; coordinates
;;
cspice_cyllat, r[i], clon_rads, z[i], radius, lon, lat
;;
;; ...convert the `lon' and `lat' values from radians to
;; degrees
;;
cspice_convrt, lon, 'RADIANS', 'DEGREES', lon_degs
cspice_convrt, lat, 'RADIANS', 'DEGREES', lat_degs
;;
;; Print the input and corresponding output.
;;
print, FORMAT='(6D9.3)', r[i], clon[i], z[i], $
radius, lon_degs, lat_degs
endfor
END
When this program was executed on a Mac/Intel/IDL8.x/64-bit
platform, the output was:
r clon z radius lon lat
------- ------- ------- ------- ------- -------
1.000 0.000 0.000 1.000 0.000 0.000
1.000 90.000 0.000 1.000 90.000 0.000
1.000 180.000 1.000 1.414 180.000 45.000
1.000 180.000 -1.000 1.414 180.000 -45.000
0.000 180.000 1.000 1.000 180.000 90.000
0.000 33.000 0.000 0.000 33.000 0.000
This routine converts coordinates given in cylindrical
coordinates to coordinates in latitudinal coordinates.
Latitudinal coordinates are defined by a distance from a central
reference point, an angle from a reference meridian, and an angle
above the equator of a sphere centered at the central reference
point.
1) If any of the input arguments, `r', `clon' or `z', is
undefined, an error is signaled by the IDL error handling
system.
2) If any of the input arguments, `r', `clon' or `z', is not of
the expected type, or it does not have the expected dimensions
and size, an error is signaled by the Icy interface.
3) If any of the output arguments, `radius', `lon' or `lat', is
not a named variable, an error is signaled by the Icy
interface.
None.
None.
ICY.REQ
None.
J. Diaz del Rio (ODC Space)
E.D. Wright (JPL)
-Icy Version 1.1.0, 17-JUN-2021 (JDR)
Edited the header to comply with NAIF standard. Added complete code
examples.
Changed the input argument name "lonc" to "clon" for consistency
with other routines.
Added -Parameters, -Exceptions, -Files, -Restrictions,
-Literature_References and -Author_and_Institution sections, and
completed -Particulars section.
Removed reference to the routine's corresponding CSPICE header from
-Abstract section.
Added arguments' type and size information in the -I/O section.
-Icy Version 1.0.0, 16-JUN-2003 (EDW)
cylindrical to latitudinal
|