Table of contents
CSPICE_DAZLDR computes the Jacobian matrix of the transformation from
rectangular to azimuth/elevation coordinates.
Given:
x,
y,
z the rectangular coordinates of the point at which the Jacobian
matrix of the map from rectangular to azimuth/elevation
coordinates is desired.
help, x
DOUBLE = Scalar
help, y
DOUBLE = Scalar
help, z
DOUBLE = Scalar
azccw a flag indicating how the azimuth is measured.
help, azccw
BOOLEAN = Scalar
If `azccw' is True, the azimuth increases in the
counterclockwise direction; otherwise it increases
in the clockwise direction.
elplsz a flag indicating how the elevation is measured.
help, elplsz
BOOLEAN = Scalar
If `elplsz' is True, the elevation increases from the
XY plane toward +Z; otherwise toward -Z.
the call:
cspice_dazldr, x, y, z, azccw, elplsz, jacobi
returns:
jacobi the matrix of partial derivatives of the transformation from
rectangular to azimuth/elevation coordinates.
help, jacobi
DOUBLE = Array[3,3]
It has the form
.- -.
| dr/dx dr/dy dr/dz |
| |
| daz/dx daz/dy daz/dz |
| |
| del/dx del/dy del/dz |
`- -'
evaluated at the input values of `x', `y', and `z'.
None.
Any numerical results shown for this example may differ between
platforms as the results depend on the SPICE kernels used as input
and the machine specific arithmetic implementation.
1) Find the azimuth/elevation state of Venus as seen from the
DSS-14 station at a given epoch. Map this state back to
rectangular coordinates as a check.
Task description
================
In this example, we will obtain the apparent state of Venus as
seen from the DSS-14 station in the DSS-14 topocentric
reference frame. We will use a station frames kernel and
transform the resulting rectangular coordinates to azimuth,
elevation and range and its derivatives using cspice_recazl and
cspice_dazldr.
We will map this state back to rectangular coordinates using
cspice_azlrec and cspice_drdazl.
In order to introduce the usage of the logical flags `azccw'
and `elplsz', we will request the azimuth to be measured
clockwise and the elevation positive towards +Z
axis of the DSS-14_TOPO reference frame.
Kernels
=======
Use the meta-kernel shown below to load the required SPICE
kernels.
KPL/MK
File name: dazldr_ex1.tm
This meta-kernel is intended to support operation of SPICE
example programs. The kernels shown here should not be
assumed to contain adequate or correct versions of data
required by SPICE-based user applications.
In order for an application to use this meta-kernel, the
kernels referenced here must be present in the user's
current working directory.
The names and contents of the kernels referenced
by this meta-kernel are as follows:
File name Contents
--------- --------
de430.bsp Planetary ephemeris
naif0011.tls Leapseconds
earth_720101_070426.bpc Earth historical
binary PCK
earthstns_itrf93_050714.bsp DSN station SPK
earth_topo_050714.tf DSN station FK
\begindata
KERNELS_TO_LOAD = ( 'de430.bsp',
'naif0011.tls',
'earth_720101_070426.bpc',
'earthstns_itrf93_050714.bsp',
'earth_topo_050714.tf' )
\begintext
End of meta-kernel.
Example code begins here.
PRO dazldr_ex1
;;
;; Local parameters
;;
FMT1 = '(A,F20.8)'
META = 'dazldr_ex1.tm'
SPICEFALSE = 0B
SPICETRUE = 1B
;;
;; Load SPICE kernels.
;;
cspice_furnsh, META
;;
;; Convert the observation time to seconds past J2000 TDB.
;;
obstim = '2003 OCT 13 06:00:00.000000 UTC'
cspice_str2et, obstim, et
;;
;; Set the target, observer, observer frame, and
;; aberration corrections.
;;
target = 'VENUS'
obs = 'DSS-14'
ref = 'DSS-14_TOPO'
abcorr = 'CN+S'
;;
;; Compute the observer-target state.
;;
cspice_spkezr, target, et, ref, abcorr, obs, state, ltime
;;
;; Convert position to azimuth/elevation coordinates,
;; with azimuth increasing clockwise and elevation
;; positive towards +Z axis of the DSS-14_TOPO
;; reference frame
;;
azccw = SPICEFALSE
elplsz = SPICETRUE
cspice_recazl, state[0:2], azccw, elplsz, r, az, el
;;
;; Convert velocity to azimuth/elevation coordinates.
;;
cspice_dazldr, state[0], state[1], state[2], azccw, elplsz, jacobi
cspice_mxv, jacobi, state[3:5], azlvel
;;
;; As a check, convert the azimuth/elevation state back to
;; rectangular coordinates.
;;
cspice_azlrec, r, az, el, azccw, elplsz, rectan
cspice_drdazl, r, az, el, azccw, elplsz, jacobi
cspice_mxv, jacobi, azlvel, drectn
print
print, format='(A)', 'AZ/EL coordinates:'
print
print, format=FMT1, ' Range (km) = ', r
print, format=FMT1, ' Azimuth (deg) = ', $
az * cspice_dpr()
print, format=FMT1, ' Elevation (deg) = ', $
el * cspice_dpr()
print
print, format='(A)', 'AZ/EL velocity:'
print
print, format=FMT1, ' d Range/dt (km/s) = ', azlvel[0]
print, format=FMT1, ' d Azimuth/dt (deg/s) = ', $
azlvel[1] * cspice_dpr()
print, format=FMT1, ' d Elevation/dt (deg/s) = ', $
azlvel[2] * cspice_dpr()
print
print, format='(A)', 'Rectangular coordinates:'
print
print, format=FMT1, ' X (km) = ', state[0]
print, format=FMT1, ' Y (km) = ', state[1]
print, format=FMT1, ' Z (km) = ', state[2]
print
print, format='(A)', 'Rectangular velocity:'
print
print, format=FMT1, ' dX/dt (km/s) = ', state[3]
print, format=FMT1, ' dY/dt (km/s) = ', state[4]
print, format=FMT1, ' dZ/dt (km/s) = ', state[5]
print
print, format='(A)', 'Rectangular coordinates from inverse mapping:'
print
print, format=FMT1, ' X (km) = ', rectan[0]
print, format=FMT1, ' Y (km) = ', rectan[1]
print, format=FMT1, ' Z (km) = ', rectan[2]
print
print, format='(A)', 'Rectangular velocity from inverse mapping:'
print
print, format=FMT1, ' dX/dt (km/s) = ', drectn[0]
print, format=FMT1, ' dY/dt (km/s) = ', drectn[1]
print, format=FMT1, ' dZ/dt (km/s) = ', drectn[2]
print
;;
;; It's always good form to unload kernels after use,
;; particularly in IDL due to data persistence.
;;
cspice_kclear
END
When this program was executed on a Mac/Intel/IDL8.x/64-bit
platform, the output was:
AZ/EL coordinates:
Range (km) = 245721478.99272084
Azimuth (deg) = 294.48543372
Elevation (deg) = -48.94609726
AZ/EL velocity:
d Range/dt (km/s) = -4.68189834
d Azimuth/dt (deg/s) = 0.00402256
d Elevation/dt (deg/s) = -0.00309156
Rectangular coordinates:
X (km) = 66886767.37916667
Y (km) = 146868551.77222887
Z (km) = -185296611.10841590
Rectangular velocity:
dX/dt (km/s) = 6166.04150307
dY/dt (km/s) = -13797.77164550
dZ/dt (km/s) = -8704.32385654
Rectangular coordinates from inverse mapping:
X (km) = 66886767.37916658
Y (km) = 146868551.77222890
Z (km) = -185296611.10841590
Rectangular velocity from inverse mapping:
dX/dt (km/s) = 6166.04150307
dY/dt (km/s) = -13797.77164550
dZ/dt (km/s) = -8704.32385654
When performing vector calculations with velocities it is
usually most convenient to work in rectangular coordinates.
However, once the vector manipulations have been performed
it is often desirable to convert the rectangular representations
into azimuth/elevation coordinates to gain insights about
phenomena in this coordinate system.
To transform rectangular velocities to derivatives of coordinates
in an azimuth/elevation coordinate system, one uses the Jacobian
matrix of the transformation between the two systems.
Given a state in rectangular coordinates
( x, y, z, dx, dy, dz )
the corresponding azimuth/elevation coordinate derivatives are
given by the matrix equation:
t | t
(dr, daz, del) = jacobi| * (dx, dy, dz)
|(x,y,z)
This routine computes the matrix
|
jacobi|
|(x, y, z)
In the azimuth/elevation coordinate system, several conventions
exist on how azimuth and elevation are measured. Using the `azccw'
and `elplsz' flags, users indicate which conventions shall be used.
See the descriptions of these input arguments for details.
1) If the input point is on the Z-axis ( x = 0 and y = 0 ), the
Jacobian matrix is undefined and therefore, the error
SPICE(POINTONZAXIS) is signaled by a routine in the call tree
of this routine.
2) If any of the input arguments, `x', `y', `z', `azccw' or
`elplsz', is undefined, an error is signaled by the IDL error
handling system.
3) If any of the input arguments, `x', `y', `z', `azccw' or
`elplsz', is not of the expected type, or it does not have the
expected dimensions and size, an error is signaled by the Icy
interface.
4) If the output argument `jacobi' is not a named variable, an
error is signaled by the Icy interface.
None.
None.
ICY.REQ
None.
J. Diaz del Rio (ODC Space)
-Icy Version 1.0.0, 17-JUN-2021 (JDR)
Jacobian matrix of AZ/EL w.r.t. rectangular coordinates
Rectangular to range, azimuth and elevation derivative
Rectangular to range, AZ and EL velocity conversion
|