Table of contents
CSPICE_WNEXPD expands each of the intervals of a double
precision window.
Given:
left the scalar, double precision amount to subtract from the left
endpoint of each interval in the input window.
help, left
DOUBLE = Scalar
right the scalar, double precision amount to add to the right endpoint
of each interval in the window.
help, right
DOUBLE = Scalar
window a window containing zero or more intervals.
help, window
STRUCT = cspice_celld(2*N)
'window' must be created as a window structure via a
cspice_celld call.
the call:
cspice_wnexpd, left, right, window
returns:
window on output, is the original window with each of its intervals
expanded by 'left' units on the left and 'right' units on the
right.
help, window
STRUCT = cspice_celld(2*N)
None.
Any numerical results shown for this example may differ between
platforms as the results depend on the SPICE kernels used as input
and the machine specific arithmetic implementation.
1) Given a double precision window, containing the following four
intervals:
[ 1.0, 3.0 ], [ 7.0, 11.0 ], [ 23.0, 27.0 ], [ 29.0, 29.0 ]
expand each interval by 2.0 units on the left and 1.0 on the
right endpoints, then by -2.0 units on the left and 2.0 units on
the right, and finally -2.0 units on the left and -1.0 units on
the right.
Example code begins here.
PRO wnexpd_ex1
;;
;; Create a cell containing a double
;; precision 8-vector.
;;
win1 = cspice_celld( 8 )
;;
;; Define a window with four intervals.
;;
darray = [ [ 1.d, 3.0], [ 7.0, 11.0], [23.0, 27.0], [29.0, 29.0] ]
;;
;; Add the window data to the cell.
;;
for i=0, 3 do begin
cspice_wninsd, darray[0,i], darray[1,i], win1
endfor
;;
;; Perform the expansion.
;;
left = 2.d
right = 1.d
cspice_wnexpd, left, right, win1
;;
;; Calculate the number of intervals in the
;; return window 'win1'.
;;
no_intervals = cspice_wncard(win1)
;;
;; Output the intervals.
;;
print, '1: Expanded window by 2 (left) and 1 (right):'
for i= 0, (no_intervals -1 ) do begin
cspice_wnfetd, win1, i, left, right
print, left, right
endfor
;;
;; Do the expansion with -2 and 2
;;
cspice_wnexpd, -2.d, 2.d, win1
print, '2: Expanded window by -2 (left) and 2 (right):'
for i= 0, (cspice_wncard(win1) -1 ) do begin
cspice_wnfetd, win1, i, left, right
print, left, right
endfor
;;
;; Do the expansion with -2 and -1
;;
cspice_wnexpd, -2.d, -1.d, win1
print, '3: Expanded window by -2 (left) and -1 (right):'
for i= 0, (cspice_wncard(win1) -1 ) do begin
cspice_wnfetd, win1, i, left, right
print, left, right
endfor
END
When this program was executed on a Mac/Intel/IDL8.x/64-bit
platform, the output was:
1: Expanded window by 2 (left) and 1 (right):
-1.0000000 4.0000000
5.0000000 12.000000
21.000000 30.000000
2: Expanded window by -2 (left) and 2 (right):
1.0000000 6.0000000
7.0000000 14.000000
23.000000 32.000000
3: Expanded window by -2 (left) and -1 (right):
3.0000000 5.0000000
9.0000000 13.000000
25.000000 31.000000
Note that intervals may be "expanded" by negative amounts.
In the example above, the second call shifts each interval to
the right, while the third call undoes the effect of the first
call (without restoring the merged intervals).
Note also that the third call is exactly equivalent to the
call:
cspice_wncond, 2.d, 1.d, window
The user must create any needed window structures with
cspice_celld prior to use regardless of whether the routine
uses the window as input or returns it as output.
This routine expands (lengthens) each of the intervals in
the input window. The adjustments are not necessarily symmetric.
That is, left units are subtracted from the left endpoint of
each interval, and right units are added to the right endpoint
of each interval, where left and right may be different.
Intervals are merged when expansion causes them to overlap.
1) The cardinality of the input `window' must be even. Left
endpoints of stored intervals must be strictly greater than
preceding right endpoints. Right endpoints must be greater
than or equal to corresponding left endpoints. Invalid window
data are not diagnosed by this routine and may lead to
unpredictable results.
2) If any of the input arguments, `left', `right' or `window', is
undefined, an error is signaled by the IDL error handling
system.
3) If any of the input arguments, `left', `right' or `window', is
not of the expected type, or it does not have the expected
dimensions and size, an error is signaled by the Icy
interface.
None.
None.
ICY.REQ
CELLS.REQ
WINDOWS.REQ
None.
J. Diaz del Rio (ODC Space)
E.D. Wright (JPL)
-Icy Version 1.0.3, 10-AUG-2021 (JDR)
Edited the header to comply with NAIF standard. Added
example's problem statement and extended example.
Extended -Particulars section.
Added -Parameters, -Exceptions, -Files, -Restrictions,
-Literature_References and -Author_and_Institution sections.
Removed reference to the routine's corresponding CSPICE header from
-Abstract section.
Added arguments' type and size information in the -I/O section.
-Icy Version 1.0.2, 26-NOV-2007 (EDW)
Implemented use of cspice_wncard function to return
window cardinality.
-Icy Version 1.0.1, 12-SEP-2006 (EDW)
Correct Required Reading citation cell.req to cells.req.
-Icy Version 1.0.0, 08-AUG-2004 (EDW)
expand the intervals of a d.p. window
|