Table of contents
CSPICE_RECLAT converts rectangular (Cartesian) coordinates to
latitudinal coordinates. All coordinates are expressed as
double precision values.
Given:
rectan a double precision 3-vector or 3xN array containing the
rectangular coordinates of a position or set of positions.
help, rectan
DOUBLE = Array[3] or DOUBLE = Array[3,N]
the call:
cspice_reclat, rectan, radius, lon, lat
returns:
radius a double precision scalar or N-vector describing the distance of
the position from origin.
help, radius
DOUBLE = Scalar or DOUBLE = Array[N]
The units associated with `radius' are those associated
with the input `rectan'.
lon a double precision scalar or N-vector describing the angle
between the prime meridian and the meridian containing the
point.
help, lon
DOUBLE = Scalar or DOUBLE = Array[N]
The direction of increasing longitude is from the +X axis
towards the +Y axis.
`lon' is output in radians. The range of `lon' is
[ -pi, pi].
lat a double precision scalar or N-vector describing the angle
measured in radians from the XY plane of the ray from the origin
through the point.
help, lat
DOUBLE = Scalar or DOUBLE = Array[N]
The range of `lat' is [-pi/2, pi/2].
`radius', `lon', and `lat' return with the same
measure of vectorization (N) as `rectan'.
None.
Any numerical results shown for these examples may differ between
platforms as the results depend on the SPICE kernels used as input
and the machine specific arithmetic implementation.
1) Compute the latitudinal coordinates of the position of the
Moon as seen from the Earth, and convert them to rectangular
coordinates.
Use the meta-kernel shown below to load the required SPICE
kernels.
KPL/MK
File name: reclat_ex1.tm
This meta-kernel is intended to support operation of SPICE
example programs. The kernels shown here should not be
assumed to contain adequate or correct versions of data
required by SPICE-based user applications.
In order for an application to use this meta-kernel, the
kernels referenced here must be present in the user's
current working directory.
The names and contents of the kernels referenced
by this meta-kernel are as follows:
File name Contents
--------- --------
de421.bsp Planetary ephemeris
naif0012.tls Leapseconds
\begindata
KERNELS_TO_LOAD = ( 'de421.bsp',
'naif0012.tls' )
\begintext
End of meta-kernel
Example code begins here.
PRO reclat_ex1
;;
;; Load SPK and LSK kernels, use a meta kernel for
;; convenience.
;;
cspice_furnsh, 'reclat_ex1.tm'
;;
;; Look up the geometric state of the Moon as seen from
;; the Earth at 2017 Mar 20, relative to the J2000
;; reference frame.
;;
cspice_str2et, '2017 Mar 20', et
cspice_spkpos, 'Moon', et, 'J2000', 'NONE', 'Earth', pos, ltime
;;
;; Convert the position vector `pos' to latitudinal
;; coordinates.
;;
cspice_reclat, pos, radius, lon, lat
;;
;; Convert the latitudinal to rectangular coordinates.
;;
cspice_latrec, radius, lon, lat, rectan
print, ' '
print, 'Original rectangular coordinates:'
print, ' '
print, format='(A,F20.8)', ' X (km): ', pos[0]
print, format='(A,F20.8)', ' Y (km): ', pos[1]
print, format='(A,F20.8)', ' Z (km): ', pos[2]
print, ' '
print, 'Latitudinal coordinates:'
print, ' '
print, format='(A,F20.8)', ' Radius (km): ', radius
print, format='(A,F20.8)', ' Longitude (deg): ', lon*cspice_dpr( )
print, format='(A,F20.8)', ' Latitude (deg): ', lat*cspice_dpr( )
print, ' '
print, 'Rectangular coordinates from cspice_latrec:'
print, ' '
print, format='(A,F20.8)', ' X (km): ', rectan[0]
print, format='(A,F20.8)', ' Y (km): ', rectan[1]
print, format='(A,F20.8)', ' Z (km): ', rectan[2]
print, ' '
END
When this program was executed on a Mac/Intel/IDL8.x/64-bit
platform, the output was:
Original rectangular coordinates:
X (km): -55658.44323296
Y (km): -379226.32931475
Z (km): -126505.93063865
Latitudinal coordinates:
Radius (km): 403626.33912495
Longitude (deg): -98.34959789
Latitude (deg): -18.26566077
Rectangular coordinates from cspice_latrec:
X (km): -55658.44323296
Y (km): -379226.32931475
Z (km): -126505.93063865
2) Create a table showing a variety of rectangular coordinates
and the corresponding latitudinal coordinates.
Corresponding rectangular and latitudinal coordinates are
listed to three decimal places. Output angles are in degrees.
Example code begins here.
PRO reclat_ex2
;;
;; Local parameters.
;;
NREC = 11
;;
;; Define the input rectangular coordinates.
;;
rectan = [[ 0.0d, 0.0d, 0.0d], $
[ 1.0d, 0.0d, 0.0d], $
[ 0.0d, 1.0d, 0.0d], $
[ 0.0d, 0.0d, 1.0d], $
[-1.0d, 0.0d, 0.0d], $
[ 0.0d, -1.0d, 0.0d], $
[ 0.0d, 0.0d, -1.0d], $
[ 1.0d, 1.0d, 0.0d], $
[ 1.0d, 0.0d, 1.0d], $
[ 0.0d, 1.0d, 1.0d], $
[ 1.0d, 1.0d, 1.0d]]
;;
;; Print the banner.
;;
print, ' rect[0] rect[1] rect[2] radius lon lat'
print, ' ------- ------- ------- ------- ------- -------'
;;
;; Do the conversion. Output angles are in degrees.
;;
for i=0, NREC - 1L do begin
cspice_reclat, rectan[*,i], radius, lon, lat
print, format='(3F9.3,$)', rectan[*,i]
print, format='(3F9.3)', radius, lon * cspice_dpr(), $
lat * cspice_dpr()
endfor
END
When this program was executed on a Mac/Intel/IDL8.x/64-bit
platform, the output was:
rect[0] rect[1] rect[2] radius lon lat
------- ------- ------- ------- ------- -------
0.000 0.000 0.000 0.000 0.000 0.000
1.000 0.000 0.000 1.000 0.000 0.000
0.000 1.000 0.000 1.000 90.000 0.000
0.000 0.000 1.000 1.000 0.000 90.000
-1.000 0.000 0.000 1.000 180.000 0.000
0.000 -1.000 0.000 1.000 -90.000 0.000
0.000 0.000 -1.000 1.000 0.000 -90.000
1.000 1.000 0.000 1.414 45.000 0.000
1.000 0.000 1.000 1.414 0.000 45.000
0.000 1.000 1.000 1.414 90.000 45.000
1.000 1.000 1.000 1.732 45.000 35.264
This routine returns the latitudinal coordinates of a point
whose position is input in rectangular coordinates.
Latitudinal coordinates are defined by a distance from a central
reference point, an angle from a reference meridian, and an angle
above the equator of a sphere centered at the central reference
point.
1) If the X and Y components of `rectan' are both zero, the
longitude is set to zero.
2) If `rectan' is the zero vector, longitude and latitude are
both set to zero.
3) If the input argument `rectan' is undefined, an error is
signaled by the IDL error handling system.
4) If the input argument `rectan' is not of the expected type, or
it does not have the expected dimensions and size, an error is
signaled by the Icy interface.
5) If any of the output arguments, `radius', `lon' or `lat', is
not a named variable, an error is signaled by the Icy
interface.
None.
None.
ICY.REQ
None.
J. Diaz del Rio (ODC Space)
E.D. Wright (JPL)
-Icy Version 1.2.0, 10-AUG-2021 (JDR)
Edited the -Examples section to comply with NAIF standard.
Added complete code examples.
Changed the output argument names "longitude" and "latitude" to
"lon" and "lat" for consistency with other routines.
Added -Parameters, -Exceptions, -Files, -Restrictions,
-Literature_References and -Author_and_Institution sections, and
completed -Particulars section.
Removed reference to the routine's corresponding CSPICE header from
-Abstract section.
Added arguments' type and size information in the -I/O section.
-Icy Version 1.1.2, 03-FEB-2009 (EDW)
Header edits performed to improve argument descriptions.
These descriptions should now closely match the descriptions
in the corresponding CSPICE routine.
Replaced the comment fragment in the -I/O section
"return with the same order"
with
"return with the same measure of vectorization"
-Icy Version 1.1.1, 09-DEC-2005 (EDW)
Added -Examples section.
-Icy Version 1.1.0, 12-SEP-2004 (EDW)
Added capability to process array 'rectan'
as input returning vectors 'radius', 'longitude',
and 'latitude' on output.
-Icy Version 1.0.0, 16-JUN-2003 (EDW)
rectangular to latitudinal coordinates
|