Table of contents
CSPICE_GFDIST determines the time intervals over which a specified
constraint on observer-target distance is met.
Given:
target the scalar string naming the target body.
help, target
STRING = Scalar
Optionally, you may supply the integer ID code for the object
as an integer string. For example both 'MOON' and '301' are
legitimate strings that indicate the moon is the target body.
The target and observer define a position vector which
points from the observer to the target; the length of
this vector is the "distance" that serves as the
subject of the search performed by this routine.
Case and leading or trailing blanks are not
significant in the string `target'.
abcorr the scalar string indicating the aberration corrections to apply
to the state evaluations to account for one-way light time and
stellar aberration.
help, abcorr
STRING = Scalar
This routine accepts the same aberration corrections as does
the Icy routine cspice_spkezr. See the header of cspice_spkezr
for a detailed description of the aberration correction
options. For convenience, the options are listed below:
'NONE' Apply no correction.
'LT' "Reception" case: correct for
one-way light time using a Newtonian
formulation.
'LT+S' "Reception" case: correct for
one-way light time and stellar
aberration using a Newtonian
formulation.
'CN' "Reception" case: converged
Newtonian light time correction.
'CN+S' "Reception" case: converged
Newtonian light time and stellar
aberration corrections.
'XLT' "Transmission" case: correct for
one-way light time using a Newtonian
formulation.
'XLT+S' "Transmission" case: correct for
one-way light time and stellar
aberration using a Newtonian
formulation.
'XCN' "Transmission" case: converged
Newtonian light time correction.
'XCN+S' "Transmission" case: converged
Newtonian light time and stellar
aberration corrections.
The `abcorr' string lacks sensitivity to case, and to embedded,
leading and trailing blanks.
obsrvr the scalar string naming the observing body.
help, obsrvr
STRING = Scalar
Optionally, you may supply the ID code of the object as an
integer string. For example, both 'EARTH' and '399' are
legitimate strings to supply to indicate the observer is the
Earth.
relate the string or character scalar describing the constraint
relational operator on observer-target distance.
help, relate
STRING = Scalar
The result window found by this routine indicates the time
intervals where the constraint is satisfied. Supported values of
`relate' and corresponding meanings are shown below:
'>' Distance is greater than the reference
value `refval'.
'=' Distance is equal to the reference
value `refval'.
'<' Distance is less than the reference
value `refval'.
'ABSMAX' Distance is at an absolute maximum.
'ABSMIN' Distance is at an absolute minimum.
'LOCMAX' Distance is at a local maximum.
'LOCMIN' Distance is at a local minimum.
The caller may indicate that the region of interest
is the set of time intervals where the quantity is
within a specified distance of an absolute extremum.
The argument `adjust' (described below) is used to
specify this distance.
Local extrema are considered to exist only in the
interiors of the intervals comprising the confinement
window: a local extremum cannot exist at a boundary
point of the confinement window.
The `relate' string lacks sensitivity to case, leading
and trailing blanks.
refval the scalar double precision reference value used together with
`relate' argument to define an equality or inequality to satisfy
by the observer-target distance.
help, refval
DOUBLE = Scalar
See the discussion of relate above for further information.
The units of `refval' are km.
adjust a scalar double precision value used to modify searches for
absolute extrema: when `relate' is set to 'ABSMAX' or 'ABSMIN'
and `adjust' is set to a positive value, cspice_gfdist finds
times when the observer-target vector coordinate is within
`adjust' radians/kilometers of the specified extreme value.
help, adjust
DOUBLE = Scalar
For `relate' set to 'ABSMAX', the result window contains
time intervals when the observer-target vector coordinate has
values between ABSMAX - adjust and ABSMAX.
For `relate' set to 'ABSMIN', the result window contains
time intervals when the observer-target distance has
values between ABSMIN and ABSMIN + adjust.
`adjust' is not used for searches for local extrema,
equality or inequality conditions.
step the scalar double precision time step size to use in the search.
help, step
DOUBLE = Scalar
`step' must be short enough for a search using this step size
to locate the time intervals where coordinate function of the
observer-target vector is monotone increasing or decreasing.
However, `step' must not be *too* short, or the search will take
an unreasonable amount of time.
The choice of `step' affects the completeness but not
the precision of solutions found by this routine; the
precision is controlled by the convergence tolerance.
See the discussion of the parameter SPICE_GF_CNVTOL for
details.
`step' has units of seconds.
nintvls a scalar integer value specifying the number of intervals in the
internal workspace array used by this routine.
help, nintvls
LONG = Scalar
`nintvls' should be at least as large as the number of
intervals within the search region on which the specified
observer-target vector coordinate function is monotone
increasing or decreasing. It does no harm to pick a value of
`nintvls' larger than the minimum required to execute the
specified search, but if chosen too small, the search will fail.
cnfine a scalar double precision window that confines the time period
over which the specified search is conducted.
help, cnfine
STRUCT = cspice_celld(2*N)
`cnfine' may consist of a single interval or a collection of
intervals.
In some cases the confinement window can be used to greatly
reduce the time period that must be searched for the desired
solution. See the -Particulars section below for further
discussion.
See the -Examples section below for a code example
that shows how to create a confinement window.
In some cases the observer's state may be computed at
times outside of `cnfine' by as much as 2 seconds. See
-Particulars for details.
the call:
cspice_gfdist, target, abcorr, obsrvr, relate, refval, $
adjust, step, nintvls, cnfine, result
returns:
result the scalar double precision window of intervals, contained
within the confinement window `cnfine', on which the specified
constraint is satisfied.
help, result
STRUCT = cspice_celld(2*R)
If `result' is non-empty on input, its contents
will be discarded before cspice_gfdist conducts its
search.
`result' must be declared and initialized with sufficient
size to capture the full set of time intervals
within the search region on which the specified constraint
is satisfied.
If the search is for local extrema, or for absolute
extrema with `adjust' set to zero, then normally each
interval of `result' will be a singleton: the left and
right endpoints of each interval will be identical.
If no times within the confinement window satisfy the
constraint, `result' will be returned with a
cardinality of zero.
SPICE_GF_CNVTOL
is the convergence tolerance used for finding endpoints
of the intervals comprising the result window.
SPICE_GF_CNVTOL is also used for finding intermediate
results; in particular, SPICE_GF_CNVTOL is used for
finding the windows on which the specified distance is
increasing or decreasing. SPICE_GF_CNVTOL is used to
determine when binary searches for roots should
terminate: when a root is bracketed within an interval
of length SPICE_GF_CNVTOL; the root is considered to
have been found.
The accuracy, as opposed to precision, of roots found
by this routine depends on the accuracy of the input
data. In most cases, the accuracy of solutions will be
inferior to their precision.
SPICE_GF_NWDIST
is the number of workspace windows required by
this routine.
See Icy header file IcyGF.pro for declarations and descriptions of
parameters used throughout the GF system.
Any numerical results shown for this example may differ between
platforms as the results depend on the SPICE kernels used as input
and the machine specific arithmetic implementation.
1) Find times during the first three months of the year 2007
when the Earth-Moon distance is greater than 400000 km.
Display the start and stop times of the time intervals
over which this constraint is met, along with the Earth-Moon
distance at each interval endpoint.
We expect the Earth-Moon distance to be an oscillatory function
with extrema roughly two weeks apart. Using a step size of one
day will guarantee that the GF system will find all distance
extrema. (Recall that a search for distance extrema is an
intermediate step in the GF search process.)
Use the meta-kernel shown below to load the required SPICE
kernels.
KPL/MK
File name: gfdist_ex1.tm
This meta-kernel is intended to support operation of SPICE
example programs. The kernels shown here should not be
assumed to contain adequate or correct versions of data
required by SPICE-based user applications.
In order for an application to use this meta-kernel, the
kernels referenced here must be present in the user's
current working directory.
The names and contents of the kernels referenced
by this meta-kernel are as follows:
File name Contents
--------- --------
de421.bsp Planetary ephemeris
pck00008.tpc Planet orientation and
radii
naif0009.tls Leapseconds
\begindata
KERNELS_TO_LOAD = ( 'de421.bsp',
'pck00008.tpc',
'naif0009.tls' )
\begintext
End of meta-kernel
Example code begins here.
PRO gfdist_ex1
MAXWIN = 1000
TIMFMT = 'YYYY-MON-DD HR:MN:SC.###### (TDB) ::TDB ::RND'
TIMLEN = 41
;;
;; Load kernels.
;;
cspice_furnsh, 'gfdist_ex1.tm'
;;
;; Store the time bounds of our search interval in
;; the cnfine confinement window.
;;
cspice_str2et, [ '2007 JAN 01', '2007 APR 01'], et
cnfine = cspice_celld( 2 )
cspice_wninsd, et[0], et[1], cnfine
;;
;; Search using a step size of 1 day (in units of
;; seconds). The reference value is 400000 km.
;; We're not using the adjustment feature, so
;; we set `adjust' to zero.
;;
step = cspice_spd()
refval = 4.D5
adjust = 0.D
target = 'MOON'
abcorr = 'NONE'
obsrvr = 'EARTH'
relate = '>'
nintvls = MAXWIN
result = cspice_celld( MAXWIN*2)
cspice_gfdist, target, abcorr, obsrvr, relate, refval, $
adjust, step, nintvls, cnfine, result
;;
;; List the beginning and ending times in each interval
;; if result contains data.
;;
count = cspice_wncard( result )
if ( count eq 0 ) then begin
print, 'Result window is empty.'
endif else begin
for i= 0L, (count - 1L ) do begin
cspice_wnfetd, result, i, left, right
cspice_timout, [left, right], TIMFMT, TIMLEN, timstr
if ( left eq right ) then begin
print, 'Event time: ', timstr[0]
endif else begin
print, 'From : ', timstr[0]
print, 'To : ', timstr[1]
print
endelse
endfor
endelse
;;
;; It's always good form to unload kernels after use,
;; particularly in IDL due to data persistence.
;;
cspice_kclear
END
When this program was executed on a Mac/Intel/IDL8.x/64-bit
platform, the output was:
From : 2007-JAN-08 00:11:07.623827 (TDB)
To : 2007-JAN-13 06:37:47.954706 (TDB)
From : 2007-FEB-04 07:02:35.279110 (TDB)
To : 2007-FEB-10 09:31:01.844110 (TDB)
From : 2007-MAR-03 00:20:25.183641 (TDB)
To : 2007-MAR-10 14:04:38.497606 (TDB)
From : 2007-MAR-29 22:53:58.147001 (TDB)
To : 2007-APR-01 00:01:05.185655 (TDB)
This routine determines a set of one or more time intervals
within the confinement window when the distance between the
specified target and observer satisfies a caller-specified
constraint. The resulting set of intervals is returned as a SPICE
window.
Below we discuss in greater detail aspects of this routine's
solution process that are relevant to correct and efficient
use of this routine in user applications.
The Search Process
==================
Regardless of the type of constraint selected by the caller, this
routine starts the search for solutions by determining the time
periods, within the confinement window, over which the
distance function is monotone increasing and monotone
decreasing. Each of these time periods is represented by a SPICE
window. Having found these windows, all of the range rate
function's local extrema within the confinement window are known.
Absolute extrema then can be found very easily.
Within any interval of these "monotone" windows, there will be at
most one solution of any equality constraint. Since the boundary
of the solution set for any inequality constraint is contained in
the union of
- the set of points where an equality constraint is met
- the boundary points of the confinement window
the solutions of both equality and inequality constraints can be
found easily once the monotone windows have been found.
Step Size
=========
The monotone windows (described above) are found via a two-step
search process. Each interval of the confinement window is
searched as follows: first, the input step size is the time
separation at which the sign of the rate of change of distance
("range rate") is sampled. Starting at the left endpoint of the
interval, samples will be taken at each step. If a change of sign
is found, a root has been bracketed; at that point, the time at
which the range rate is zero can be found by a refinement
process, for example, via binary search.
Note that the optimal choice of step size depends on the lengths
of the intervals over which the distance function is monotone:
the step size should be shorter than the shortest of these
intervals (within the confinement window).
The optimal step size is *not* necessarily related to the lengths
of the intervals comprising the result window. For example, if
the shortest monotone interval has length 10 days, and if the
shortest result window interval has length 5 minutes, a step size
of 9.9 days is still adequate to find all of the intervals in the
result window. In situations like this, the technique of using
monotone windows yields a dramatic efficiency improvement over a
state-based search that simply tests at each step whether the
specified constraint is satisfied. The latter type of search can
miss solution intervals if the step size is longer than the
shortest solution interval.
Having some knowledge of the relative geometry of the target and
observer can be a valuable aid in picking a reasonable step size.
In general, the user can compensate for lack of such knowledge by
picking a very short step size; the cost is increased computation
time.
Note that the step size is not related to the precision with which
the endpoints of the intervals of the result window are computed.
That precision level is controlled by the convergence tolerance.
Convergence Tolerance
=====================
As described above, the root-finding process used by this routine
involves first bracketing roots and then using a search process
to locate them. "Roots" include times when extrema are attained
and times when the distance function is equal to a reference
value or adjusted extremum. All endpoints of the intervals
comprising the result window are either endpoints of intervals of
the confinement window or roots.
Once a root has been bracketed, a refinement process is used to
narrow down the time interval within which the root must lie.
This refinement process terminates when the location of the root
has been determined to within an error margin called the
"convergence tolerance." The default convergence tolerance
used by this routine is set by the parameter SPICE_GF_CNVTOL (defined
in IcyGF.pro).
The value of SPICE_GF_CNVTOL is set to a "tight" value so that the
tolerance doesn't become the limiting factor in the accuracy of
solutions found by this routine. In general the accuracy of input
data will be the limiting factor.
The user may change the convergence tolerance from the default
SPICE_GF_CNVTOL value by calling the routine cspice_gfstol, e.g.
cspice_gfstol, tolerance value
Call cspice_gfstol prior to calling this routine. All subsequent
searches will use the updated tolerance value.
Setting the tolerance tighter than SPICE_GF_CNVTOL is unlikely to be
useful, since the results are unlikely to be more accurate.
Making the tolerance looser will speed up searches somewhat,
since a few convergence steps will be omitted. However, in most
cases, the step size is likely to have a much greater effect
on processing time than would the convergence tolerance.
The Confinement Window
======================
The simplest use of the confinement window is to specify a time
interval within which a solution is sought. However, the
confinement window can, in some cases, be used to make searches
more efficient. Sometimes it's possible to do an efficient search
to reduce the size of the time period over which a relatively
slow search of interest must be performed. See the "CASCADE"
example program in gf.req for a demonstration.
Certain types of searches require the state of the observer,
relative to the solar system barycenter, to be computed at times
slightly outside the confinement window `cnfine'. The time window
that is actually used is the result of "expanding" `cnfine' by a
specified amount "T": each time interval of `cnfine' is expanded by
shifting the interval's left endpoint to the left and the right
endpoint to the right by T seconds. Any overlapping intervals are
merged. (The input argument `cnfine' is not modified.)
The window expansions listed below are additive: if both
conditions apply, the window expansion amount is the sum of the
individual amounts.
- If a search uses an equality constraint, the time window
over which the state of the observer is computed is expanded
by 1 second at both ends of all of the time intervals
comprising the window over which the search is conducted.
- If a search uses stellar aberration corrections, the time
window over which the state of the observer is computed is
expanded as described above.
When light time corrections are used, expansion of the search
window also affects the set of times at which the light time-
corrected state of the target is computed.
In addition to the possible 2 second expansion of the search
window that occurs when both an equality constraint and stellar
aberration corrections are used, round-off error should be taken
into account when the need for data availability is analyzed.
1) In order for this routine to produce correct results,
the step size must be appropriate for the problem at hand.
Step sizes that are too large may cause this routine to miss
roots; step sizes that are too small may cause this routine
to run unacceptably slowly and in some cases, find spurious
roots.
This routine does not diagnose invalid step sizes, except that
if the step size is non-positive, an error is signaled by a
routine in the call tree of this routine.
2) Due to numerical errors, in particular,
- Truncation error in time values
- Finite tolerance value
- Errors in computed geometric quantities
it is *normal* for the condition of interest to not always be
satisfied near the endpoints of the intervals comprising the
result window.
The result window may need to be contracted slightly by the
caller to achieve desired results. The SPICE window routine
cspice_wncond can be used to contract the result window.
3) If an error (typically cell overflow) occurs while performing
window arithmetic, the error is signaled by a routine
in the call tree of this routine.
4) If the relational operator `relate' is not recognized, an
error is signaled by a routine in the call tree of this
routine.
5) If the aberration correction specifier contains an
unrecognized value, an error is signaled by a routine in the
call tree of this routine.
6) If `adjust' is negative, an error is signaled by a routine in
the call tree of this routine.
7) If either of the input body names do not map to NAIF ID
codes, an error is signaled by a routine in the call tree of
this routine.
8) If required ephemerides or other kernel data are not
available, an error is signaled by a routine in the call tree
of this routine.
9) If the number of intervals `nintvls' is less than 1, the error
SPICE(VALUEOUTOFRANGE) is signaled by a routine in the call
tree of this routine.
10) If the result window has size less than 2, the error
SPICE(INVALIDDIMENSION) is signaled by a routine in the call
tree of this routine.
11) If the output SPICE window `result' has insufficient capacity
to contain the number of intervals on which the specified
distance condition is met, an error is signaled
by a routine in the call tree of this routine.
12) If any of the input arguments, `target', `abcorr', `obsrvr',
`relate', `refval', `adjust', `step', `nintvls', `cnfine' or
`result', is undefined, an error is signaled by the IDL error
handling system.
13) If any of the input arguments, `target', `abcorr', `obsrvr',
`relate', `refval', `adjust', `step', `nintvls', `cnfine' or
`result', is not of the expected type, or it does not have the
expected dimensions and size, an error is signaled by the Icy
interface.
Appropriate kernels must be loaded by the calling program before
this routine is called.
The following data are required:
- SPK data: ephemeris data for target and observer for the
time period defined by the confinement window must be
loaded. If aberration corrections are used, the states of
target and observer relative to the solar system barycenter
must be calculable from the available ephemeris data.
Typically ephemeris data are made available by loading one
or more SPK files via cspice_furnsh.
- If non-inertial reference frames are used, then PCK
files, frame kernels, C-kernels, and SCLK kernels may be
needed.
- In some cases the observer's state may be computed at times
outside of `cnfine' by as much as 2 seconds; data required to
compute this state must be provided by loaded kernels. See
-Particulars for details.
Kernel data are normally loaded once per program run, NOT every
time this routine is called.
1) The kernel files to be used by this routine must be loaded
(normally via the Icy routine cspice_furnsh) before this routine
is called.
GF.REQ
ICY.REQ
NAIF_IDS.REQ
SPK.REQ
TIME.REQ
WINDOWS.REQ
None.
J. Diaz del Rio (ODC Space)
E.D. Wright (JPL)
-Icy Version 1.0.2, 03-NOV-2021 (JDR)
Added -Parameters, -Exceptions, -Files, -Restrictions,
-Literature_References and -Author_and_Institution sections.
Updated header to describe use of expanded confinement window.
Edited the header to comply with NAIF standard. Corrected typos in
header.
Added meta-kernel used in the example.
Removed reference to the routine's corresponding CSPICE header from
-Abstract section.
Added arguments' type and size information in the -I/O section.
-Icy Version 1.0.1, 05-SEP-2012 (EDW)
Edit to comments to correct search description.
Header updated to describe use of cspice_gfstol.
-Icy Version 1.0.0, 15-APR-2009 (EDW)
GF distance search
|