Table of contents
CSPICE_DRDAZL computes the Jacobian matrix of the transformation from
azimuth/elevation to rectangular coordinates.
Given:
range the distance from the origin of the input point specified by
`range', `az', and `el'.
help, range
DOUBLE = Scalar
Negative values for `range' are not allowed.
Units are arbitrary and are considered to match those
of the rectangular coordinate system associated with the
output matrix `jacobi'.
az the azimuth of the point.
help, az
DOUBLE = Scalar
This is the angle between the projection onto the XY plane of
the vector from the origin to the point and the +X axis of
the reference frame. `az' is zero at the +X axis.
The way azimuth is measured depends on the value of
the logical flag `azccw'. See the description of the
argument `azccw' for details.
The range (i.e., the set of allowed values) of `az' is
unrestricted. See the -Exceptions section for a
discussion on the `az' range.
Units are radians.
el the elevation of the point.
help, el
DOUBLE = Scalar
This is the angle between the vector from the origin to the
point and the XY plane. `el' is zero at the XY plane.
The way elevation is measured depends on the value of
the logical flag `elplsz'. See the description of the
argument `elplsz' for details.
The range (i.e., the set of allowed values) of `el' is
[-pi/2, pi/2], but no error checking is done to ensure
that `el' is within this range. See the -Exceptions
section for a discussion on the `el' range.
Units are radians.
azccw a flag indicating how the azimuth is measured.
help, azccw
BOOLEAN = Scalar
If `azccw' is True, the azimuth increases in the
counterclockwise direction; otherwise `az' increases
in the clockwise direction.
elplsz if a flag indicating how the elevation is measured.
help, elplsz
BOOLEAN = Scalar
If `elplsz' is True, the elevation increases from
the XY plane toward +Z; otherwise toward -Z.
the call:
cspice_drdazl, range, az, el, azccw, elplsz, jacobi
returns:
jacobi the matrix of partial derivatives of the transformation from
azimuth/elevation to rectangular coordinates.
help, jacobi
DOUBLE = Array[3,3]
It has the form
.- -.
| dx/drange dx/daz dx/del |
| |
| dy/drange dy/daz dy/del |
| |
| dz/drange dz/daz dz/del |
`- -'
evaluated at the input values of `range', `az' and `el'.
`x', `y', and `z' are given by the familiar formulae
x = range * cos( az ) * cos( el )
y = range * sin( azsnse * az ) * cos( el )
z = range * sin( eldir * el )
where `azsnse' is +1 when `azccw' is True and -1
otherwise, and `eldir' is +1 when `elplsz' is True
and -1 otherwise.
None.
Any numerical results shown for this example may differ between
platforms as the results depend on the SPICE kernels used as input
and the machine specific arithmetic implementation.
1) Find the azimuth/elevation state of Venus as seen from the
DSS-14 station at a given epoch. Map this state back to
rectangular coordinates as a check.
Task description
================
In this example, we will obtain the apparent state of Venus as
seen from the DSS-14 station in the DSS-14 topocentric
reference frame. We will use a station frames kernel and
transform the resulting rectangular coordinates to azimuth,
elevation and range and its derivatives using cspice_recazl and
cspice_dazldr.
We will map this state back to rectangular coordinates using
cspice_azlrec and cspice_drdazl.
In order to introduce the usage of the logical flags `azccw'
and `elplsz', we will request the azimuth to be measured
clockwise and the elevation positive towards +Z
axis of the DSS-14_TOPO reference frame.
Kernels
=======
Use the meta-kernel shown below to load the required SPICE
kernels.
KPL/MK
File name: drdazl_ex1.tm
This meta-kernel is intended to support operation of SPICE
example programs. The kernels shown here should not be
assumed to contain adequate or correct versions of data
required by SPICE-based user applications.
In order for an application to use this meta-kernel, the
kernels referenced here must be present in the user's
current working directory.
The names and contents of the kernels referenced
by this meta-kernel are as follows:
File name Contents
--------- --------
de430.bsp Planetary ephemeris
naif0011.tls Leapseconds
earth_720101_070426.bpc Earth historical
binary PCK
earthstns_itrf93_050714.bsp DSN station SPK
earth_topo_050714.tf DSN station FK
\begindata
KERNELS_TO_LOAD = ( 'de430.bsp',
'naif0011.tls',
'earth_720101_070426.bpc',
'earthstns_itrf93_050714.bsp',
'earth_topo_050714.tf' )
\begintext
End of meta-kernel.
Example code begins here.
PRO drdazl_ex1
;;
;; Local parameters
;;
FMT1 = '(A,F20.8)'
META = 'drdazl_ex1.tm'
SPICEFALSE = 0B
SPICETRUE = 1B
;;
;; Load SPICE kernels.
;;
cspice_furnsh, META
;;
;; Convert the observation time to seconds past J2000 TDB.
;;
obstim = '2003 OCT 13 06:00:00.000000 UTC'
cspice_str2et, obstim, et
;;
;; Set the target, observer, observer frame, and
;; aberration corrections.
;;
target = 'VENUS'
obs = 'DSS-14'
ref = 'DSS-14_TOPO'
abcorr = 'CN+S'
;;
;; Compute the observer-target state.
;;
cspice_spkezr, target, et, ref, abcorr, obs, state, ltime
;;
;; Convert position to azimuth/elevation coordinates,
;; with azimuth increasing clockwise and elevation
;; positive towards +Z axis of the DSS-14_TOPO
;; reference frame
;;
azccw = SPICEFALSE
elplsz = SPICETRUE
cspice_recazl, state[0:2], azccw, elplsz, r, az, el
;;
;; Convert velocity to azimuth/elevation coordinates.
;;
cspice_dazldr, state[0], state[1], state[2], azccw, elplsz, jacobi
cspice_mxv, jacobi, state[3:5], azlvel
;;
;; As a check, convert the azimuth/elevation state back to
;; rectangular coordinates.
;;
cspice_azlrec, r, az, el, azccw, elplsz, rectan
cspice_drdazl, r, az, el, azccw, elplsz, jacobi
cspice_mxv, jacobi, azlvel, drectn
print
print, format='(A)', 'AZ/EL coordinates:'
print
print, format=FMT1, ' Range (km) = ', r
print, format=FMT1, ' Azimuth (deg) = ', $
az * cspice_dpr()
print, format=FMT1, ' Elevation (deg) = ', $
el * cspice_dpr()
print
print, format='(A)', 'AZ/EL velocity:'
print
print, format=FMT1, ' d Range/dt (km/s) = ', azlvel[0]
print, format=FMT1, ' d Azimuth/dt (deg/s) = ', $
azlvel[1] * cspice_dpr()
print, format=FMT1, ' d Elevation/dt (deg/s) = ', $
azlvel[2] * cspice_dpr()
print
print, format='(A)', 'Rectangular coordinates:'
print
print, format=FMT1, ' X (km) = ', state[0]
print, format=FMT1, ' Y (km) = ', state[1]
print, format=FMT1, ' Z (km) = ', state[2]
print
print, format='(A)', 'Rectangular velocity:'
print
print, format=FMT1, ' dX/dt (km/s) = ', state[3]
print, format=FMT1, ' dY/dt (km/s) = ', state[4]
print, format=FMT1, ' dZ/dt (km/s) = ', state[5]
print
print, format='(A)', 'Rectangular coordinates from inverse mapping:'
print
print, format=FMT1, ' X (km) = ', rectan[0]
print, format=FMT1, ' Y (km) = ', rectan[1]
print, format=FMT1, ' Z (km) = ', rectan[2]
print
print, format='(A)', 'Rectangular velocity from inverse mapping:'
print
print, format=FMT1, ' dX/dt (km/s) = ', drectn[0]
print, format=FMT1, ' dY/dt (km/s) = ', drectn[1]
print, format=FMT1, ' dZ/dt (km/s) = ', drectn[2]
print
;;
;; It's always good form to unload kernels after use,
;; particularly in IDL due to data persistence.
;;
cspice_kclear
END
When this program was executed on a Mac/Intel/IDL8.x/64-bit
platform, the output was:
AZ/EL coordinates:
Range (km) = 245721478.99272084
Azimuth (deg) = 294.48543372
Elevation (deg) = -48.94609726
AZ/EL velocity:
d Range/dt (km/s) = -4.68189834
d Azimuth/dt (deg/s) = 0.00402256
d Elevation/dt (deg/s) = -0.00309156
Rectangular coordinates:
X (km) = 66886767.37916667
Y (km) = 146868551.77222887
Z (km) = -185296611.10841590
Rectangular velocity:
dX/dt (km/s) = 6166.04150307
dY/dt (km/s) = -13797.77164550
dZ/dt (km/s) = -8704.32385654
Rectangular coordinates from inverse mapping:
X (km) = 66886767.37916658
Y (km) = 146868551.77222890
Z (km) = -185296611.10841590
Rectangular velocity from inverse mapping:
dX/dt (km/s) = 6166.04150307
dY/dt (km/s) = -13797.77164550
dZ/dt (km/s) = -8704.32385654
It is often convenient to describe the motion of an object
in azimuth/elevation coordinates. It is also convenient to
manipulate vectors associated with the object in rectangular
coordinates.
The transformation of an azimuth/elevation state into an
equivalent rectangular state makes use of the Jacobian matrix
of the transformation between the two systems.
Given a state in latitudinal coordinates,
( r, az, el, dr, daz, del )
the velocity in rectangular coordinates is given by the matrix
equation
t | t
(dx, dy, dz) = jacobi| * (dr, daz, del)
|(r,az,el)
This routine computes the matrix
|
jacobi|
|(r,az,el)
In the azimuth/elevation coordinate system, several conventions
exist on how azimuth and elevation are measured. Using the `azccw'
and `elplsz' flags, users indicate which conventions shall be used.
See the descriptions of these input arguments for details.
1) If the value of the input parameter `range' is negative, the
error SPICE(VALUEOUTOFRANGE) is signaled by a routine in the
call tree of this routine.
2) If the value of the input argument `el' is outside the
range [-pi/2, pi/2], the results may not be as
expected.
3) If the value of the input argument `az' is outside the
range [0, 2*pi], the value will be mapped to a value
inside the range that differs from the input value by an
integer multiple of 2*pi.
4) If any of the input arguments, `range', `az', `el', `azccw' or
`elplsz', is undefined, an error is signaled by the IDL error
handling system.
5) If any of the input arguments, `range', `az', `el', `azccw' or
`elplsz', is not of the expected type, or it does not have the
expected dimensions and size, an error is signaled by the Icy
interface.
6) If the output argument `jacobi' is not a named variable, an
error is signaled by the Icy interface.
None.
None.
ICY.REQ
None.
J. Diaz del Rio (ODC Space)
-Icy Version 1.0.0, 30-DEC-2021 (JDR)
Jacobian matrix of rectangular w.r.t. AZ/EL coordinates
range, azimuth and elevation to rectangular derivative
Range, AZ and EL to rectangular velocity conversion
|