DESIGNATE PLANETOGRAPHIC

Syntax

Fixed

   DESIGNATE @int(1001:10099)
      CENTER @body
      REFERENCE PLANETOGRAPHIC
      (2:3){ LATITUDE  @number
           | LONGITUDE @number
           | @options
           | HEIGHT    @number }
      (0:3){ FROM  @calendar
           | TO    @calendar
           | EPOCH @calendar }

Moving

   DESIGNATE @int(1001:10099)
      CENTER @body
      REFERENCE PLANETOGRAPHIC
      (2:3){ LATITUDE  (1:2)@number
           | LONGITUDE (1:2)@number
           | @options
           | HEIGHT    (1:2)@number }
      EPOCH @calendar
      (0:2){ FROM @calendar
           | TO   @calendar }

Description

When creating a designated object in this system, you must specify the latitude and longitude of the object. The height above the reference spheroid is optional. If left unspecified, the height defaults to zero.

Definition

The reference spheroid is generated from the tri-axial ellipsoid used to model the reference body by setting both equatorial radii equal to the longer one.

In planetographic coordinates, the z-axis points toward the north pole of the reference body. The x-axis is defined by the intersection of the equator and prime meridian of the body. The origin is at the center of the body.

Let P be a point in space, and let V be the position vector from the origin of the planetographic frame to P.

To find the planetographic longitude of a P, project V onto the x-y plane. The longitude is the angle between the x-axis and the projection. By definition, the planetographic longitude of the sub-Earth point increases with time. (Thus, longitude is negative from x toward y for bodies with direct rotation, but positive from x toward y for bodies with retrograde rotation.)

To find the planetographic latitude of P, find the surface normal on the reference spheroid that passes through P. The latitude is the angle between the equator and the normal. North latitudes are positive, south latitudes are negative.

The planetographic height of P is the distance from P to the point nearest P on the reference spheroid.

Examples

Example 1

The following example uses the DESIGNATE PLANETOGRAPHIC command to place a designated object at the volcano Olympus Mons on the surface of Mars.

   DEFINE OLYMPUS 1002;
 
   DESIGNATE OLYMPUS
        CENTER              MARS
        REFERENCE PLANETOGRAPHIC
        LATITUDE      28 DEGREES
        LONGITUDE    134 DEGREES;

Example 2

While Percy is designed to plan observations from spacecraft, it can also be used to plan observations---or just simulate the view---from terrestrial observatories, as in the following example.

   DEFINE KITT_PEAK 1003;
 
   DESIGNATE KITT_PEAK
        CENTER        EARTH
        REFERENCE     PLANETOGRAPHIC
        LATITUDE    31.95000 DEGREES
        LONGITUDE -111.61667 DEGREES
        HEIGHT       2.08 KM ;
 
   SET VANTAGE KITT_PEAK;
   SET POINTING AT JUPITER;
   DRAW GRIDS CLIP STARS BORDER;