C=======================================================================C
C									C
	REAL FUNCTION L_s( ET )
C									C
C=======================================================================C
C									C
C   This program computes Mars Solar Longitude (L_s, deg) at requested	C
C   input time ET (ephemeris seconds from J2000).			C
C									C
C   Epoch time when L_s   = 0:   1998 JAN 07 11:10:00.000 (TL)		C
C   Epoch time when M = L = 0;   1998 JUL 14 19:02:30.000 (TR)		C
C									C
C=======================================================================C
C									C
C	VERSION 1.00		T. Duxbury	    29 May 1995		C
C									C
C=======================================================================C

	IMPLICIT NONE

C   Double Precision variables

	DOUBLE PRECISION
     *		ET,		! Ephemeris time, sec past J2000
     *		TR		! Epoch time of Mars periapsis, ET 

	REAL
     *		DPR,		! Degrees / radian, ~57.3
     *		E,		! Mars orbital eccentricity
     *		L,		! Mars orbital true anomoly, deg
     *		L_0, 		! Epoch value of L_s @ TR, deg
c    *		L_s, 		! Mars solar longitude, deg
     *		M 		! Mars orbital mean anomoly, deg

	DATA	
     *		DPR /   57.295780 /
     *		E   /   0.0933865 /
     *		L_0 /  109.033055 /    ! L_s @ July 14 1998 19:02:30
     *		TR  /  -62556538.8158849D0 / ! July 14 1998 19:02:30

C   Compute the current Mars orbital Mean Anomoly at ET, deg

	M  = DMOD( (360.D0 / 687.09D0) * (( ET - TR ) / 86400.D0 ),
     *		    360.D0 )

C   Use a 3rd order expansion in orbital eccentricity to approximate
C   the Mars orbital true anomoly, deg

	L  = M + DPR * ( ( 2.0 * E + 0.25 * E**3 ) * SIND( M )
     *		       +  1.25 * E**2 * SIND( 2.0*M ) +
     *		          13.0 * E**3 * SIND( 3.0*M ) / 12.0 )

C   Compute the Mars solar longitude, deg

	L_s = AMOD( L - L_0, 360.0 )	! deg
	IF( L_s .LT. 0.0 ) L_s = L_s + 360.0
	
	RETURN
	END






